__FILE__和__LINE__的Flex / actionscript 3等效项

Question

我对flex / actionscript很新，我想知道是否有相当于php（和其他语言）的 FILE 和 LINE 标识符？

基本上我想做一些自定义错误记录，并希望像：

 var mymessage:String = 'Oops, a hiccup occured at ' + __FILE__ + ', line: ' + __LINE__; 

在编译时将文件和行代替其值。

这可能吗？

Answer 1

这不是直接可行的，但是有一个相当有用的个人测试解决方法

var stackTrace:String = new Error().getStackTrace();
if (stackTrace) {
    var mymessage:String = "Oops, a hiccup occurred " + stackTrace.split("\n")[1];
}

调整您对getStackTrace的滥用情况。

Answer 2

添加Cory对上述内容的回答。首先添加：

-define=CONFIG::debugging,true

到库的编译器设置（“Additional Compiler Arguments”中的“-locale en_US”旁边）。然后使用这个快速库：

package ddd
{
  public class Stack
  {
    protected static function str(val:*):String
    {
      if( val == null      ) return "<null>";
      if( val == undefined ) return "<undefined>";
      return val.toString();
    }

    protected static var removeAt :RegExp = /^\s*at\s*/i;
    protected static var matchFile:RegExp = /[(][)][\[][^:]*?:[0-9]+[\]]\s*$/i;
    protected static var trimFile :RegExp = /[()\[\]\s]*/ig;

    /* Must maintain number of stack levels, so that _stack can assume the 4th line of getStackTrace */
    private static function _stack( msg:String="", ...params ):String
    {
      var s   :String = new Error().getStackTrace();
      var func:String = "??";
      var file:String = "??";
      var args:String = null;
      if(s)
      {
        func = s.split("\n")[4];
        func = func.replace( removeAt, "" );
        var farr:Array  = func.match( matchFile );
        if( farr != null && farr.length > 0 ) file = farr[0].replace( trimFile, "" );
        func = func.replace( matchFile, "" );
      }
      for each( var param:* in params )
      {
        args = ( args == null ? "" : args.concat(",") );
        args = args.concat( str(param) );
      }
      return func + "(" + (args==null?"":args) + ")" + ( (msg!=null && msg!="") ? ":"+msg : "" ) + " at " + file;
    }

    /* Must maintain number of stack levels, so that _stack can assume the 4th line of getStackTrace */
    public static function stack( msg:String="", ...params ):String
    {
      params.unshift( msg );
      return _stack.apply( null, params );
    }

    /* Must maintain number of stack levels, so that _stack can assume the 4th line of getStackTrace */
    public static function pstack( msg:String="", ...params ):void
    {
      CONFIG::debugging {
        params.unshift(msg);
        trace( _stack.apply( null, params ) );
      }
    }
  }
}

然后你可以打电话：

Stack.pstack();

在任何函数内部打印该位置的堆栈位置，如下所示：

package::classname/function() at /wherever/src/package/classname.mxml:999

只需记住在编译生产之前将调试设置为false，剩下的就是一个空的pstack调用，什么都不做 - guts将被条件编译出来。

Answer 3

恕我直言，该行或文件不会在Flex中添加太多信息。我通常输出类和方法名称，因为我的方法往往很短，所以通常很清楚发生了什么。

如果你发现自己的方法有数百行，你应该重新考虑你的编码风格。