Question

我正在使用此脚本来计算文件的时间：

set "filename=myfile.txt"
rem extract current date and time
for /f "tokens=1-5 delims=.:, " %%a in ("%date% %time%") do (
  set day=%%a&set mon=%%b&set yr=%%c&set hr=%%d&set min=%%e
)
rem extract file date and time
for /f "tokens=1-5 delims=.:, " %%a in ('"dir %filename%|find "%filename%""') do 
(
  set fday=%%a&set fmon=%%b&set fyr=%%c&set fhr=%%d&set fmin=%%e
)
rem calculate age of file (in minutes)
set /a "age=((hr*60+min)-(fhr*60+fmin)+(24*60))%%(24*60)"
set /a "max=8"
if %age% geq %max% echo.file is older than 8 minutes

但是我有一些错误并且要纠正我必须使用以下条件：

 if %hr% EQU 08 set hr=8
 if %hr% EQU 09 set hr=9
 if %min% EQU 08 set min=8
 if %min% EQU 09 set min=9
 if %fhr% EQU 08 set fhr=8
 if %fhr% EQU 09 set fhr=9
 if %fmin% EQU 08 set fmin=8
 if %fmin% EQU 09 set fmin=9

是否有一种更简单的方法可以解决问题而无需使用我创建的那些条件？

Answer 1

正如我上面评论的那样，纯数批在日期数学上很糟糕。这是一个混合批处理/ JScript脚本，它可以非常容易地计算文件的年龄（编辑：或目录）。无需担心小时翻转，白天更改，夏令时或任何其他垃圾。从1970年1月1日午夜开始，基于毫秒的所有简单的柠檬挤压都是如此。

@if (@CodeSection==@Batch) @then

:: age.bat filename.ext
:: get age of file in minutes

@echo off
setlocal

if "%~1"=="" echo Usage: age.bat filename.ext && goto :EOF
if not exist "%~1" echo %1 not found. && goto :EOF

for /f %%I in ('cscript /nologo /e:JScript "%~f0" "%~1"') do (
    echo %1 is %%I minutes old.

    rem :: Now use "if %%I gtr 4" here to take whatever actions you wish
    rem :: on files that are over 4 minutes old.

)

goto :EOF

:: end batch portion / begin JScript
@end

var fso = new ActiveXObject("scripting.filesystemobject"),
    arg = WSH.Arguments(0),
    file = fso.FileExists(arg) ? fso.GetFile(arg) : fso.GetFolder(arg);

// Use either DateCreated, DateLastAccessed, or DateLastModified.
// See http://msdn.microsoft.com/en-us/library/1ft05taf%28v=vs.84%29.aspx
// for more info.

var age = new Date() - file.DateLastModified;
WSH.Echo(Math.floor(age / 1000 / 60));

有关批处理/ JScript混合脚本的更多信息，请see this GitHub page。上面使用的样式类似于该页面上的Hybrid.bat。

批处理文件中的文件超过4分钟

1 个答案: