Question

您好我想创建一个bat文件来使用cmd重命名文件。说一个朋友，我一起去度假。我们将所有图片放在一起，现在我想按顺序重命名所有图片。

说我选择了以下图片：

mypicture_3435.jpg（档案日期= 2015年1月1日10:00）
mypicture_3465.jpg（档案日期= 2015年1月4日12:00）
myfriendspicture_2221.jpg（档案日期= 2015年1月3日12:00）
myfriendspicture_2226.jpg（档案日期= 2015年1月4日11:00）

我想得到以下输出：

ourvacation_01.jpg [mypicture_3435.jpg（档案日期= 2015年1月1日 10:00）]
ourvacation_02.jpg [myfriendspicture_2221.jpg（档案日期= 03 2015年1月12日）]
ourvacation_03.jpg [myfriendspicture_2226.jpg（文件 date = 04 Jan 2015 11:00）]
ourvacation_04.jpg [mypicture_3465.jpg （档案日期= 2015年1月4日12:00）]

使用特定软件（如acdsee）甚至Windows图像浏览器都可以轻松完成。但是我想用命令promt来做。（我在一所学校教数学，我想用它作为一个编程实例）。

我尝试了以下脚本并且有效：

@echo off
setlocal EnableDelayedExpansion
set i=0
for %%a in (*.jpg) do (
    set /a i+=1
    ren "%%a" "!i!.new"
)
ren *.new *.jpg

但它重命名了这样的文件：

myfriendspicture_2221.jpg变为1.jpg
myfriendspicture_2226.jpg变为2.jpg
mypicture_3435.jpg变为3.jpg
mypicture_3465.jpg变为4.jpg

所以问题是：

他们没有按时间顺序排列。
如果我说了11个项目，并按名称排序，则序列分别为1,10,11,2,3,4 ...

我尝试在重命名之前运行dir / od，但它不起作用，序列根据文件名运行。

我发现的有关此问题的所有字符串都会将当前日期和时间附加到文件名，但不会将文件日期和时间附加到它自己的名称。

我找不到在序列中添加前导0或00的方法，以便文件名和时间顺序匹配。

非常感谢您的帮助。

Answer 1

我尝试在重命名之前运行dir / od，但它没有工作，序列根据文件名运行。

您是否只是运行dir /od然后for %%a in (*.jpg)？您是如何计划捕获dir /od的输出以使其有用，而不是仅仅将其转储到stdout？

每当您想捕获命令的输出时，请使用for /f循环。您应该将这两个命令组合在一起：

for /f "delims=" %%I in ('dir /b /o:d *.jpg') do stuff.

下一期：零填充文件名。我们可以假设您的假期中没有超过10,000张照片吗？然后只在你生成的文件名前面加上四个零，然后使用right-most 4 characters来确定你的图片的基本名称。

@echo off
setlocal enabledelayedexpansion

set /a seq=10001
for /f "delims=" %%I in ('dir /b /o:d *.jpg') do (

    rem :: remove the "echo" when you are ready to rename
    echo ren "%%~I" "ourvacation_!seq:~-4!.jpg"

    set /a seq += 1
)

结果看起来像这样：

C:\Users\me\Desktop>test.bat
ren "avatar65929_2.jpg" "ourvacation_0001.jpg"
ren "IMG_20140621_190332.jpg" "ourvacation_0002.jpg"
ren "funny-Finding-Neverland-scene-Explorer.jpg" "ourvacation_0003.jpg"
ren "5DFPwMa.jpg" "ourvacation_0004.jpg"
ren "funny-root-math-equation.jpg" "ourvacation_0005.jpg"
ren "196889_145889312230730_1041953273_n.jpg" "ourvacation_0006.jpg"
ren "0001-cf72d77a-509ac348-b92c-fe8af7d2.jpg" "ourvacation_0007.jpg"
ren "IMG_20141230_191526.jpg" "ourvacation_0008.jpg"
ren "20150120_142150.jpg" "ourvacation_0009.jpg"
ren "20150120_145223.jpg" "ourvacation_0010.jpg"

使用cmd将文件日期附加到文件名

1 个答案: