Question

嘿伙计们我正在尝试使用转换XML文档将表直接输出到excel中。我遇到的问题是我需要通过子节点对元素进行分组。我目前的XSLT是这样的：

    <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="ScanData">
  <html>
  <body>
  <xsl:for-each select="Report/ReportHost">
    <xsl:if test="ReportItem/@severity &gt; 0">
    <h2><xsl:value-of select="@name"/></h2><br/>
    </xsl:if>
    <xsl:for-each select="ReportItem">
        <xsl:sort select = "@severity" data-type="number" order="descending"/>
        <xsl:sort select = "@pluginID"/>
    <xsl:if test="@severity &gt; 0">
    <xsl:if test="(preceding-sibling::*[1]/@pluginName != @pluginName)">
    <b>Severity: </b><xsl:value-of select="@severity"/><br/>
    <b>Name: </b><xsl:value-of select="@pluginName"/><br/>  
    <b>Synopsis: </b><xsl:value-of select="synopsis"/><br/> 
    <b>Description: </b><xsl:value-of select="description"/><br/>   
    <b>Solution: </b><xsl:value-of select="solution"/><br/> 
    </xsl:if>
    Port:<xsl:value-of select="@protocol"/>/<xsl:value-of select="@port"/><br/>
    </xsl:if>
     </xsl:for-each>
      </xsl:for-each>
  </body>
  </html>
</xsl:template>
</xsl:stylesheet>

示例XML

<?xml version="1.0" ?>
    <?xml-stylesheet type="text/xsl" href="Internal.xsl"?>
    <ScanData>
        <Report name="Report">
            <ReportHost name="192.168.1.1">      
                <ReportItem port="0" svc_name="general" protocol="tcp" severity="1" pluginID="11936" pluginName="OS Identification" pluginFamily="General">
                    <description>Using a combination of remote probes (TCP/IP, SMB, HTTP, NTP, SNMP, etc...), it is possible to guess the name of the remote operating system in use. It is also sometimes possible to guess the version of the operating system.</description>
                    <fname>os_fingerprint.nasl</fname>
                    <plugin_modification_date>2014/02/19</plugin_modification_date>
                    <plugin_name>OS Identification</plugin_name>
                    <plugin_publication_date>2003/12/09</plugin_publication_date>
                    <plugin_type>combined</plugin_type>
                    <risk_factor>None</risk_factor>
                    <script_version>$Revision: 2.37 $</script_version>
                    <solution>n/a</solution>
                    <synopsis>It is possible to guess the remote operating system.</synopsis>

                </ReportItem>
.....(ReportItem and ReportHost repeat with different findings and hosts)

我遇到的问题是所有数据都是按主机地址输出的，但我需要通过pluginID对数据进行分组，因此我不需要“拥有这些结果的主机”，而是需要“使用这些主机进行查找”。
即：
当前：
的 ReportHost / @名称
查找属性（名称，描述等）
受影响的港口
受影响的港口
受影响的港口
查找属性（名称，描述等）
受影响的端口

ReportHost / @名称
查找属性（名称，描述等）
受影响的港口
受影响的港口
。
。
。

必需：
查找属性（名称，描述等）
的 ReportHost / @名称
受影响的港口
受影响的港口
受影响的港口
的 ReportHost / @名称
受影响的端口

查找属性（名称，描述等）
的 ReportHost / @名称
受影响的港口
受影响的港口
。
。

我知道我说我需要excel，而且我已经为excel创建了一个可行的XSL我只是使用HTML来方便测试（没有工具只是记事本++和Firefox）。对不起，如果我没解释得很好。我认为我需要使用Muenchian Grouping，因为每个组都不允许使用excel，但我是一个XML noob，我似乎无法理解它。

提前致谢。

詹姆斯

Answer 1

你确实需要Muenchian Grouping。事实上，你需要使用它两次。首先，您通过插件对ReportItem元素进行分组，因此您可以像这样定义一个键（注意我已经在严重性中包含了条件，因为它从您现有的XSLT中看起来只需要具有非零严重性的项目）

<xsl:key name="plugin" match="ReportItem[@severity > 0]" use="@pluginID" />

在这个＆＃34;组内＆＃34;然后你需要通过ReportHost对插件进行分组。为此，您可以定义第二个键，但因为它是一个＆＃34;组内的组＆＃34;你仍然需要引用插件ID：

<xsl:key name="plugin_by_report" match="ReportItem[@severity > 0]" use="concat(@pluginID, '|', ../@name)" />

请注意使用..获取父ReportHost元素

然后，要获得不同的插件，请使用第一个键

在此群组中，要按ReportHost获取不同的项目，请执行此操作

<xsl:for-each 
     select="key('plugin', @pluginID)
             [generate-id() = generate-id(key('plugin_by_report',concat(@pluginID, '|', ../@name))[1])]">

为初学者尝试这个XSL：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:output method="xml" indent="yes" />

<xsl:key name="plugin" match="ReportItem[@severity > 0]" use="@pluginID" />
<xsl:key name="plugin_by_report" match="ReportItem[@severity > 0]" use="concat(@pluginID, '|', ../@name)" />

<xsl:template match="ScanData">
    <html>
        <body>
            <xsl:for-each select="Report/ReportHost/ReportItem[generate-id() = generate-id(key('plugin', @pluginID)[1])]">
                <h2>Plugin: <xsl:value-of select="@pluginName"/></h2>
                <xsl:for-each select="key('plugin', @pluginID)[generate-id() = generate-id(key('plugin_by_report',concat(@pluginID, '|', ../@name))[1])]">
                    <h3>Host: <xsl:value-of select="../@name"/></h3>
                    <xsl:apply-templates select="key('plugin_by_report',concat(@pluginID, '|', ../@name))">
                    <xsl:sort select = "@severity" data-type="number" order="descending"/>
                    </xsl:apply-templates>
                </xsl:for-each>
            </xsl:for-each>
        </body>
    </html>
</xsl:template>

<xsl:template match="ReportItem">
    <p>
    Port:<xsl:value-of select="@protocol"/>/<xsl:value-of select="@port"/>
    </p>
</xsl:template>
</xsl:stylesheet>

XSL：使用匹配的子属性组合父属性

1 个答案: