Question

所以我想为一个简单的c ++程序编写语法。

这就是语法现在的样子：

PDefs. Program ::= [Def] ;
terminator Def "" ;
comment "//" ;
comment "/*" "*/" ;
comment "#" ;
DFun. Def ::= Type Id "(" [Arg] ")" "{" [Stm] "}" ;
separator Arg "," ;
terminator Stm "" ;
ADecl. Arg ::= Type Id ;
SExp. Stm ::= Exp ";" ;
SDecl. Stm ::= Type Id ";" ;
SDecls. Stm ::= Type Id "," [Id] ";" ;
SInit. Stm ::= Type Id "=" Exp ";" ;
SReturn. Stm ::= "return" Exp ";" ;
SWhile. Stm ::= "while" "(" Exp ")" Stm ;
SBlock. Stm ::= "{" [Stm] "}" ;
SIfElse. Stm ::= "if" "(" Exp ")" Stm "else" Stm ;


EInt. Exp15 ::= Integer ;
EDouble. Exp15 ::= Double ;
ETrue. Exp15 ::= "true" ;
EFalse. Exp15 ::= "false" ;
EId. Exp15 ::= Id ;
EApp. Exp15 ::= Id "(" [Exp] ")" ;
EPIncr. Exp14 ::= Exp15 "++" ;
EPDecr. Exp14 ::= Exp15 "--" ;
EIncr. Exp13 ::= "++" Exp14 ;
EDecr. Exp13 ::= "--" Exp14 ;
ETimes. Exp12 ::= Exp12 "*" Exp13 ;
EDiv. Exp12 ::= Exp12 "/" Exp13 ;
EPlus. Exp11 ::= Exp11 "+" Exp12 ;
EMinus. Exp11 ::= Exp11 "-" Exp12 ;
ELt. Exp9 ::= Exp9 "<" Exp10 ;
EGt. Exp9 ::= Exp9 ">" Exp10 ;
ELtEq. Exp9 ::= Exp9 "<=" Exp10 ;
EGtWq. Exp9 ::= Exp9 ">=" Exp10 ;
EEq. Exp8 ::= Exp8 "==" Exp9 ;
ENEq. Exp8 ::= Exp8 "!=" Exp9 ;
EAnd. Exp4 ::= Exp4 "&&" Exp5 ;
EOr. Exp3 ::= Exp3 "||" Exp4 ;
EAss. Exp2 ::= Exp3 "=" Exp2 ;

coercions Exp 15 ;
separator Exp "," ;
separator Id "," ;

Tbool. Type ::= "bool" ;
Tdouble. Type ::= "double" ;
Tint. Type ::= "int" ;
Tvoid. Type ::= "void" ;

token Id (letter (letter | digit | '_')*) ;

这是需要解析的简单c ++程序

// a small C++ program
#include <iostream>

int main()
{
    std::cout << "Hello, world!" << std::endl;
    return 0;
}

所以当我尝试解析它时，我得到第6行中的错误，意思是std :: cout行。由于我是bnf的新手，我不知道如何＆＃34;思考＆＃34;解决这个问题。如果有人能举例说明你将如何解决这样的情况会很棒。！

谢谢！

Answer 1

失败的行无法解析，因为您缺少某些规则：

您需要一条规则来解析合格ID 合格ID是一种特殊类型的标识符，可以（出于您的目的）在与（不合格）标识符相同的情况下使用。
std::cout和std::endl是有资格的ID，对它们的（简化）规则可能如下所示：
```
<qualified_id> ::= <nested_name_specifier> <unqualified_id>
<nested_name_specifier> ::= <namespace_name> "::" <nested_name_specifier>?
```
其中（为了您的目的），＆lt; unqualified_id＆gt; 和＆lt; namespace_name＆gt; 可被视为标识符。
您需要使用 <<运算符解析表达式的规则。
此附加类型表达式的（简化）规则可能如下所示：
```
<shift_left_expression> ::= <other_expression>
<shift_left_expression> ::= <shift_left_expression> "<<" <other_expression>
```
其中（为了您的目的）＆lt; other_expression＆gt; 代表任何其他类型的表达。
您需要一条规则来解析字符串文字 字符串文字是一种文字，它可以（作为您的目的）用作表达式的一部分，如标识符。
"Hello, world!"是一个字符串文字，它们的（简化）规则可能如下所示：
```
<string_literal> ::= "\"" <s_char_sequence>? "\""
<s_char_sequence> ::= <s_char>
<s_char_sequence> ::= <s_char_sequence> <s_char>
```
其中＆lt; s_char＆gt; 是您希望在字符串文字中允许的任何字符（为了保持简单，请不要在其中使用"字符，例如。）

一个简单的c ++程序示例的BNF语法

1 个答案: