Question

我试图获得从0到n的增量，然后从n-1减少到0，并反复重复该循环。

在这个以Processing编写的例子中，我希望背景逐渐从黑色（i = 0）变为白色（i = 255），然后逐渐变为白色到黑色等等。现在我只能让它从黑色变为白色，然后它突然变回黑色。

int i = 0;

void setup(){
size(640, 360);
frameRate(60);
}
void draw(){
  background(i);
  i++;
  if(i==256){i=0;}
}

Answer 1

尝试 -

 int change = 1;
 void draw(){
  background(i);
  i = i + change;
  if(i==256){change = -1;}
  if(i==0){change = 1;}
}

Answer 2

另一种看待这个问题的方法是：＆＃34;我怎么画三角波？＆＃34;。我喜欢这种方式，因为它不需要＆＃34; ifs＆＃34;。像这样的事情就可以了。

triangleWave = maxNumber - abs(incrementedVar % (2*maxNumber) - maxNumber);

Coll，不是吗？

我有这个旧代码使用它，它不是绘制波形，而是使用它来表示大小和填充颜色。还有一个用于比较的正弦波。看看：

float zigZag, toIncrement, speed =1, maxNumber = 255;
float sine, x = 270, speed2 = 1;

void setup() {
  size(800, 400);
  background(255);
}
void draw() {
  background(255);

  //triangle wave
  toIncrement+=speed;
  zigZag = maxNumber - abs(toIncrement % (2*maxNumber) - maxNumber);
  fill(zigZag);
  noStroke();
  ellipse( 150, height/2+100, 50, 50);
  strokeWeight(zigZag);
  stroke(0);
  line(100, height/2-100, 200, height/2-100);
  text("triangle = " + int(zigZag), 100, height-30);
  println("triangle wave value = " + zigZag);


  //sine wave
  x+=speed2;
  sine = (1+sin(radians(x)))*(maxNumber/2);
  fill(sine);
  noStroke();
  ellipse( 650, height/2+100, 50, 50);
  strokeWeight(sine);
  stroke(0);
  line(600, height/2-100, 700, height/2-100);
  fill(80);
  text("sine = " + int(sine), 600, height-30);
}

如何连续增量后减量？

2 个答案: