Question

我试图在Haskell中编写通用的向量空间实现。我的实现如下：

import qualified GHC.Generics as G
import GHC.Generics hiding (V1)

class GVecSpace v where
  addVs :: v -> v -> v
  scaleV :: Double -> v -> v

instance GVecSpace (G.V1 a) where
  addVs _ _ = undefined
  scaleV _ _ = undefined

instance GVecSpace (G.U1 a) where
  addVs _ x = x -- no value
  scaleV _ x = x -- no value

instance (GVecSpace (f a), GVecSpace (g a)) => GVecSpace ((f :+: g) a) where
  addVs (L1 x) (L1 y) = L1 $ addVs x y
  addVs (R1 x) (R1 y) = R1 $ addVs x y
  scaleV d (L1 x) = L1 $ scaleV d x
  scaleV d (R1 x) = R1 $ scaleV d x

instance (GVecSpace (f a), GVecSpace (g a)) => GVecSpace ((f :*: g) a) where
  addVs (x1 :*: x2) (y1 :*: y2) =
    addVs x1 y1 :*: addVs x2 y2
  scaleV d (x1 :*: x2) =
    scaleV d x1 :*: scaleV d x2

instance (GVecSpace c) => GVecSpace (K1 i c p) where
  addVs (K1 x) (K1 y) = K1 $ addVs x y
  scaleV d (K1 x) = K1 $ scaleV d x

instance (GVecSpace (f p)) => GVecSpace (M1 i c f p) where
  addVs (M1 x) (M1 y) = M1 $ addVs x y
  scaleV d (M1 x) = M1 $ scaleV d x

instance (Generic a, GVecSpace (Rep a)) => GVecSpace a where
  addVs x y =
    G.to $ addVs (G.from x) (G.from y)
  scaleV d x =
    G.to $ scaleV d (G.from x)

但GHC抱怨因为Rep a有错误的类型：

Expecting one more argument to ‘Rep a’
The first argument of ‘GVecSpace’ should have kind ‘*’,
  but ‘Rep a’ has kind ‘* -> *’
In the instance declaration for ‘GVecSpace a’

我应该改变什么来使这项工作？一种选择是让GVecSpace仅适用于各种* -> *，但这看起来很尴尬。有没有办法避免这种情况？

Answer 1

要创建使用GHC.Generics的库，我们首先需要一些先决条件。

{-# LANGUAGE DefaultSignatures #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE FlexibleContexts #-}

import GHC.Generics as G

泛型的所有表示都带有一个名为“参数”p的额外类型参数。您可以在Rep a类Generic a中的type Rep a :: * -> *类型中看到此类型。数据类型的表示不仅仅是另一种数据类型，它是类型为* -> *的类型，与Functor和Monad的类型相同。它需要另一种类型作为参数。大多数时候，基于通用表示来定义类的实例，我们将忽略参数。

由于额外的参数，定义非泛型类很有用。我们稍后会添加更多内容。

class VecSpace v where
    addVs :: v -> v -> v
    scaleV :: Double -> v -> v

    ...

类的通用版本GVecSpace在所有值的类型上都有一个额外的参数a。我们之前使用v的任何地方都会使用f a。我们将GVecSpace的新名称添加到g的名称前面VecSpace。

class GVecSpace f where
    gaddVs :: f a -> f a -> f a
    gscaleV :: Double -> f a -> f a

GVecSpace类有点尴尬，仅适用于* -> *类，但它仅用于制作VecSpace的默认实现。您将在其他任何地方使用VecSpace。

只有一个构造函数的单元类型是向量空间。请注意，G.U1未应用于参数。

instance GVecSpace G.U1 where
  gaddVs _ x = x -- no value
  gscaleV _ x = x -- no value

两个向量空间的乘积是向量空间。请注意，f和g以及f :*: g未应用于参数类型。

instance (GVecSpace f, GVecSpace g) => GVecSpace (f :*: g) where
  gaddVs (x1 :*: x2) (y1 :*: y2) =
    gaddVs x1 y1 :*: gaddVs x2 y2
  gscaleV d (x1 :*: x2) =
    gscaleV d x1 :*: gscaleV d x2

对于K1，我们从类型中删除最终参数p，并根据非通用VecSpace进行定义。 c参数只有*种，是普通类型，因此它不能是GVecSpace的实例。

instance (VecSpace c) => GVecSpace (K1 i c) where
  gaddVs (K1 x) (K1 y) = K1 $ addVs x y
  gscaleV d (K1 x) = K1 $ scaleV d x

对于M1元数据节点，我们从类型中删除最终参数p。

instance (GVecSpace f) => GVecSpace (M1 i c f) where
  gaddVs (M1 x) (M1 y) = M1 $ gaddVs x y
  gscaleV d (M1 x) = M1 $ gscaleV d x

现在我们可以返回VecSpace类，并在其表示具有VecSpace实例时填写GVecSpace内容的默认值。我们将参数转换为表达式from类型v，对表示执行操作的通用版本，然后在我们'时将to类型转换回v重做。

class VecSpace v where
    addVs :: v -> v -> v
    scaleV :: Double -> v -> v

    default addVs :: (Generic v, GVecSpace (Rep v)) => v -> v -> v
    addVs x y = to (gaddVs (from x) (from y))

    default scaleV :: (Generic v, GVecSpace (Rep v)) => Double -> v -> v
    scaleV s = to . gscaleV s . from

使用

假设您已经观察到Double s形成了一个向量空间

instance VecSpace Double where
    addVs = (+)
    scaleV = (*)

我们可以根据VecSpace中的default为元组派生一个有效的VecSpace实例。

instance (VecSpace a, VecSpace b) => VecSpace (a, b)

与GHC.Generics有点不匹配

1 个答案:

使用