Question

当前的curry函数接受一个接受2个元素元组的函数，并允许将结果函数调整或部分应用。

let x = curry (\(x, y) -> x + y)
x 1 2 -- 3

是否可以创建一个咖喱函数来处理元组中包含N个元素的函数？

我尝试创建它，但我不确定1：类型签名，2：如何反转参数。

curryN f 0 = f
curryN f n = \a -> (curryN (f) (n-1)) a

curryN (\(x, y, z) -> x + y + z) 3
-- I assume it looks something like: \a -> (\a -> (\a -> (f) a) a) a but I'm not sure

OR

curryN f 0 =  f
curryN f n = curryN (\a - > f a) (n -1)

另一方面，这样的功能可以发现元素的数量，而不是需要告诉这个数字是什么？

Answer 1

实现此类功能的方法之一是使用GHC.Generics。使用这种方法，我们甚至不需要传递许多参数（或元组大小）。这是有效的，因为有一个为元组定义的Generic实例，它有效地将元组转换为树结构（类型为Rep a），然后我们可以从右向左遍历（使用此处的延续传递样式）生成沿途的curried函数并将这些参数的值打包成相同的Rep a结构，然后将其转换为带有to函数的元组并传递给原始的非curried函数参数。此代码仅使用类型级参数树（未使用from函数），因为我们生成元组而不是接收它。这种方法的唯一限制是Generic仅定义为最多八元素元组。

{-# LANGUAGE TypeOperators, MultiParamTypeClasses,
  FlexibleInstances, UndecidableInstances,
  TypeFamilies, ScopedTypeVariables #-}

import GHC.Generics


-- | class for `curryN` function
class CurryN t r where
    type CurriedN t r :: *
    curryN :: (t -> r) -> CurriedN t r

-- | Implementation of curryN which uses GHC.Generics
instance (Generic t, GCurryN (Rep t) r) => CurryN t r where
    type CurriedN t r = GCurriedN (Rep t) r
    curryN f = gcurryN (f . to)

-- | Auxiliary class for generic implementation of `curryN`
--   Generic representation of a tuple is a tree of its elements
--   wrapped into tuple constructor representation
--   We need to fold this tree constructing a curried function
--   with parameters corresponding to every elements of the tuple
class GCurryN f r where
    type GCurriedN f r :: *
    gcurryN :: (f p -> r) -> GCurriedN f r

-- | This matches tuple definition
--   Here we extract tree of tuple parameters and use other instances to "fold" it into function
instance (GCurryN f r) => GCurryN (D1 e1 (C1 e2 f)) r where
    type GCurriedN (D1 e1 (C1 e2 f)) r = GCurriedN f r
    gcurryN c = gcurryN (\t -> c (M1 (M1 t)))

-- | A node of the tree (combines at least two parameters of the tuple)
instance (GCurryN b r, GCurryN a (GCurriedN b r)) => GCurryN (a :*: b) r where
    type GCurriedN (a :*: b) r = GCurriedN a (GCurriedN b r)
    gcurryN c = gcurryN (\a -> gcurryN (\b -> c (a :*: b)))

-- | A leaf of the tree (a single tuple parameter)
instance GCurryN (S1 NoSelector (Rec0 a)) r where
    type GCurriedN (S1 NoSelector (Rec0 a)) r = a -> r
    gcurryN c = \a -> c $ M1 (K1 a)


-- Examples of usage
t2 = curryN (uncurry (&&))

t3 = curryN (\(a,b,c) -> a + b + c)

t4 = curryN (\(a,b,c,d) -> ((a , b) , (c , d)))

tf = curryN (\(f,a,xs) -> foldr f a xs)

t5 = curryN (\(a,b,c,d,e) -> (a ++ b , c - d, not e))

t7 = curryN (\(a1,a2,a3,a4,a5,a6,a7) -> a7)

Haskell，是否可以创建一个咖喱函数，可以存储任意数量的元组元素

1 个答案: