Question

我可以使用SYB的gfoldl一次性完成listify结果的地图吗？

例如考虑以下代码：

extractNums :: Expr -> [Int]
extractNums e = map numVal $ listify isNum e

  where isNum :: Expr -> Bool
        isNum (Num _) = True
        isNum _       = False

        numVal :: Expr -> Int
        numVal (Num i) = i
        numVal _       = error "Somehow filter did not work?"

我不喜欢numVal函数中的那个我必须考虑Expr类型的不同数据构造函数，而我只对Num构造函数感兴趣。我宁愿用下面的vals函数替换isNum和numVals：

    vals :: [Int] -> Expr -> [Int]
    vals xs (Num x) = x : xs
    vals xs _       = xs

这可以用gfoldl完成吗？怎么样？

Answer 1

也许这不是最优雅的方法，但这是我的尝试：

extractNums :: Expr -> [Int]
extractNums e = everything (++) (mkQ [] q) e
   where q (Num n) = [n]
         q _ = []

但我希望它的表现低于标准。使用flip (++)的Maye会更好吗？我现在无法看到它。

另一方面，我刚刚意识到listify的定义方式类似。所以它至少比你现在的情况更糟糕。

或者，正如下面的@Alex所建议的那样：

import qualified Data.DList as D

extractNums :: Expr -> [Int]
extractNums e = D.toList $ everything (D.append) (mkQ D.empty q) e
   where q (Num n) = D.singleton n
         q _ = D.empty

Answer 2

函数listify定义为

-- | Get a list of all entities that meet a predicate
listify :: Typeable r => (r -> Bool) -> GenericQ [r]
listify p = everything (++) ([] `mkQ` (\x -> if p x then [x] else []))

类似于filter。我们可以创建一个类似mapMaybe的替代方案，将您需要的map和filter组合成一个：

import Data.Generics
import Data.Generics.Schemes
import Data.Maybe (maybeToList)
import Data.Typeable

listify' :: (Typeable t) => (t -> Maybe r) -> GenericQ [r]
listify' f = everything (++) ([] `mkQ` (maybeToList . f))

然后您的示例可以表示为

numVal :: Expr -> Maybe Int
numVal (Num i) = Just i
numVal _       = Nothing

test :: Expr -> [Int]
test = listify' numVal

SYB：可以用gfoldl重写listify结果的映射吗？

2 个答案: