Question

嗨，我有这个文本文件。

Physical interface: ge-0/0/3, Enabled, Physical link is Up
  Interface index: 132, SNMP ifIndex: 504
  Description: # SURVEILLANCE CAMERA #
  Link-level type: Flexible-Ethernet, Media type: Copper, MTU: 9000,
  LAN-PHY mode, Link-mode: Full-duplex, Speed: 1000mbps, BPDU Error: None,
   .....few more lines
Physical interface: ge-0/1/0, Enabled, Physical link is Down
  Interface index: 133, SNMP ifIndex: 505
  Link-level type: Ethernet, Media type: Fiber, MTU: 1514, LAN-PHY mode,
  Speed: 1000mbps, BPDU Error: None, MAC-REWRITE Error: None,
    .....few more lines
Physical interface: ge-0/1/3, Enabled, Physical link is Up
  Interface index: 136, SNMP ifIndex: 508
  Description: # TO CSS_I-TN-CHNN-ENB-I099 #
  Link-level type: Flexible-Ethernet, Media type: Fiber, MTU: 8000,
  LAN-PHY mode, Speed: 1000mbps, BPDU Error: None, MAC-REWRITE Error: None,
   ... few more lines

 and so on....

现在如果物理链接是Up＆amp; MTU的值是9000然后我只需要将相应的行替换为。

<Pass>Physical interface: ge-0/0/3, Enabled, Physical link is Up
&
<Pass>Link-level type: Flexible-Ethernet, Media type: Fiber, MTU: 9000,

在其他所有情况下，<Fail>代替<Pass>。这些值存在于不同的界限，为什么我不知道使用sed或其他任何东西..请帮助......这里是预期的输出..

 <Pass>Physical interface: ge-0/0/3, Enabled, Physical link is Up
      Interface index: 132, SNMP ifIndex: 504
      Description: # SURVEILLANCE CAMERA #
      <Pass>Link-level type: Flexible-Ethernet, Media type: Copper, MTU: 9000,
      LAN-PHY mode, Link-mode: Full-duplex, Speed: 1000mbps, BPDU Error: None,
         .....few more lines
  <Fail>Physical interface: ge-0/1/0, Enabled, Physical link is Down
     Interface index: 133, SNMP ifIndex: 505
     <Fail>Link-level type: Ethernet, Media type: Fiber, MTU: 1514, LAN-PHY mode,
     Speed: 1000mbps, BPDU Error: None, MAC-REWRITE Error: None,
            .....few more lines
   <Fail>Physical interface: ge-0/1/3, Enabled, Physical link is Up
     Interface index: 136, SNMP ifIndex: 508
     Description: # TO CSS_I-TN-CHNN-ENB-I099 #
     <Fail>Link-level type: Flexible-Ethernet, Media type: Fiber, MTU: 8000,
     LAN-PHY mode, Speed: 1000mbps, BPDU Error: None, MAC-REWRITE Error: None,
           ... few more lines

         and so on....

Answer 1

使用sed：

sed '/Physical link is/ { :a /MTU:/! { N; ba; }; /Physical link is Up.*MTU: 9000/ { s/\(.*\n\)\s*/<Pass>\1<Pass>/; b; }; s/\(.*\n\)\s*/<Fail>\1<Fail>/; }' filename

那是：

/Physical link is/ {                       # Block start found
  :a
  /MTU:/! {                                # fetch lines until we find the MTU
    N
    ba
  }
  /Physical link is Up.*MTU: 9000/ {       # If link is up and MTU 9000
    s/\(.*\n\)[[:space:]]*/<Pass>\1<Pass>/ # insert Pass markers
    b
                                           # we're done.
  }
  s/\(.*\n\)[[:space:]]*/<Fail>\1<Fail>/   # otherwise insert Fail markers
}

请注意，对于BSD sed，由于b指令，因此不能将其用作单行。在这种情况下，将扩展的（没有注释，对于BSD sed容易混淆）代码放在文件中，比如foo.sed，并使用sed -f foo.sed filename。我已经用其POSIX等价物（\s）替换了其他GNU-ism（[[:space:]]）。

要将空格保留在MTU行的开头，请移除\s或[[:space:]]。要在结果标记之前放置空格，请将\s或[[:space:]]放入捕获组（即\(.*\n\s*\)）。

另请注意：这假设每个接口描述都有一个MTU字段。

或者，您可以尝试使用此awk脚本：

awk -v RS='Physical interface:' -F '\n' -v OFS='\n' '{ result = "<Fail>" } /Physical link is Up/ && /MTU: 9000/ { result = "<Pass>" } NR != 1 { for(i = 1; i <= NF; ++i) { if(index($i, "MTU:")) { sub(/^ */, result, $i) } } print result RS $0 }' filename

这会将文件拆分为Physical interface:处的记录，并将记录拆分为换行符中的字段。然后：

{ result = "<Fail>" }                  # result is Fail 
/Physical link is Up/ && /MTU: 9000/ { # unless link is up and MTU 9000
  result = "<Pass>"
}

NR != 1 {                              # the first record is the empty string
                                       # before the first actual record, so
                                       # we remove it.
  for(i = 1; i <= NF; ++i) {           # wade through the fields (lines)
    if(index($i, "MTU:")) {            # find the MTU line
      sub(/^ */, result, $i)           # put the marker there. To keep the
                                       # whitespace, use $i = result $i
                                       # instead, or sub(/^ */, "&" result, $i)
                                       # to keep the spaces before the marker.
    }
  }
  print result RS $0                   # once done, print the whole shebang.
                                       # We have to reinsert the record
                                       # separator because it was removed
                                       # by the splitting.
}

请注意，多字符RS并非严格符合POSIX标准。但最常见的问题（gawk和mawk）支持它。值得注意的是，BSD awk没有。

Answer 2

尝试使用以下awk命令，该命令应符合POSIX标准并保留前导空格：

awk '
 / Physical link is / { ++count }
 /, MTU: / {
    tag = (blockLines[1] ~ /Up$/ && $0 ~ /, MTU: 9000,/ ? "<Pass>" : "<Fail>")
    sub(/^/, "&" tag, blockLines[1])
    sub(/^ +/, "&" tag)
    for (i = 1; i < count; ++i) print blockLines[i]
    count = 0
 }
 count > 0 { blockLines[count++] = $0; next }
 { print }
' file

基本理念是：

收集一个行块 - 所有行之间的所有行（包括必须标记的两行） - 在一个数组中而不打印它们。
到达块的末尾，确定必须使用哪个标记（失败或通过）
打印块中的所有行，相应地标记第一行和最后一行。

仅限Awk脚本的带注释的版本：

 / Physical link is / { ++count } # Start of block
 /, MTU: / {                      # End of block - fail/pass can now be determined
    # Determine whether to apply a fail or a pass tag based on the
    # first and last line in the block.
    tag = (blockLines[1] ~ /Up$/ && $0 ~ /, MTU: 9000,/ ? "<Pass>" : "<Fail>")
    # Prepend tag to 1st line in block
    sub(/^/, "&" tag, blockLines[1])
    # Prepend tag to last line in block, preserving leading whitespace.
    sub(/^ +/, "&" tag)
    # Print all lines in block (except for last one).
    for (i = 1; i < count; ++i) print blockLines[i]
    # Reset block line counter.
    count = 0
 }
 # Inside block: collect lines, do not print yet.
 count > 0 { blockLines[count++] = $0; next }
 # Print last line in block and lines outside of blocks.
 { print }

如何匹配＆amp;然后在shell脚本中替换多行

2 个答案: