Question

我需要转换这个输入XML：

<Log1>
    <Connection User="Peter" Host="Computer01" Port="22"/>
    <Connection User="Peter" Host="Computer02" Port="22"/>
    <Connection User="Peter" Host="Computer02" Port="80"/>
    <Connection User="David" Host="Computer01" Port="8080"/>
    <Connection User="David" Host="Computer01" Port="8080"/>
    <Connection User="David" Host="Computer01" Port="8080"/>
    <Connection User="David" Host="Computer03" Port="22"/>
    <Connection User="David" Host="Computer04" Port="21"/>
</Log1>

进入输出XML：

<Log2>
    <Event Name="David" Target="Computer01|Computer03|Computer04"/>
    <Event Name="Peter" Target="Computer01|Computer02"/>            
</Log2>

到目前为止，我使用了Muenchian分组并获得了类似的内容：

<Log2>      
    <Event Name="David" Target="Computer01|Computer01|Computer01|Computer03|Computer04"/>   
    <Event Name="Peter" Target="Computer01|Computer02|computer02"/>
</Log2>

问题是我无法摆脱输出中的重复机器。

这是我的XSLT：

<xsl:key name="myKey" match="Connection" use="@User"/>
<xsl:variable name="separator" select="'|'"/>

<xsl:template match="Log1"> 
    <xsl:element name="Log2">       
        <xsl:for-each select="Connection[count(. | key('myKey', @User)[1]) = 1]">
            <xsl:sort select="@User" />
            <xsl:element name="Event">
                <xsl:attribute name="Name">
                    <xsl:value-of select="@User" />
                </xsl:attribute>
                <xsl:attribute name="Target">
                    <xsl:for-each select="key('myKey', @User)">
                        <xsl:sort select="@Host" />
                        <xsl:value-of select="@Host" />
                        <xsl:if test="position() != last()">
                            <xsl:value-of select="$separator" />            
                        </xsl:if>
                    </xsl:for-each>
                </xsl:attribute>
            </xsl:element>
        </xsl:for-each>         
    </xsl:element> 
</xsl:template>

你们可以帮我使用XSLT 1.0处理器吗？

Answer 1

您实际上需要在此处执行第二组Muenchian分组，因为您还需要对“User”和“Host”的组合进行分组，以便为每个用户获取不同的Host属性。所以，你需要第二个键，如下：

<xsl:key name="myKey2" match="Connection" use="concat(@User, '|', @Host)"/>

（请注意，管道|可以是此处的任何内容，只要它在User或Host中都不会出现。

然后你在你的内心xsl:for-each中使用如下：

<xsl:for-each select="key('myKey', @User)[count(. | key('myKey2', concat(@User, '|', @Host))[1]) = 1]">

试试这个XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:key name="myKey" match="Connection" use="@User"/>
<xsl:key name="myKey2" match="Connection" use="concat(@User, '|', @Host)"/>
<xsl:variable name="separator" select="'|'"/>

<xsl:template match="Log1"> 
    <xsl:element name="Log2">       
        <xsl:for-each select="Connection[count(. | key('myKey', @User)[1]) = 1]">
            <xsl:sort select="@User" />
            <xsl:element name="Event">
                <xsl:attribute name="Name">
                    <xsl:value-of select="@User" />
                </xsl:attribute>
                <xsl:attribute name="Target">
                    <xsl:for-each select="key('myKey', @User)[count(. | key('myKey2', concat(@User, '|', @Host))[1]) = 1]">
                        <xsl:sort select="@Host" />
                        <xsl:value-of select="@Host" />
                        <xsl:if test="position() != last()">
                            <xsl:value-of select="$separator" />            
                        </xsl:if>
                    </xsl:for-each>
                </xsl:attribute>
            </xsl:element>
        </xsl:for-each>         
    </xsl:element> 
</xsl:template>
</xsl:stylesheet>

作为旁注，没有必要使用xsl:element来创建具有静态名称的元素，只需直接写出元素即可。例如

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="myKey" match="Connection" use="@User"/>
<xsl:key name="myKey2" match="Connection" use="concat(@User, '|', @Host)"/>
<xsl:variable name="separator" select="'|'"/>

<xsl:template match="Log1"> 
    <Log2>       
        <xsl:for-each select="Connection[count(. | key('myKey', @User)[1]) = 1]">
            <xsl:sort select="@User" />
            <Event Name="{@User}">
                <xsl:attribute name="Target">
                    <xsl:for-each select="key('myKey', @User)[count(. | key('myKey2', concat(@User, '|', @Host))[1]) = 1]">
                        <xsl:sort select="@Host" />
                        <xsl:value-of select="@Host" />
                        <xsl:if test="position() != last()">
                            <xsl:value-of select="$separator" />            
                        </xsl:if>
                    </xsl:for-each>
                </xsl:attribute>
            </Event>
        </xsl:for-each>         
    </Log2> 
</xsl:template>
</xsl:stylesheet>

另请注意在创建Name属性时使用属性值模板。

XSLT1转换

1 个答案: