Question

我遇到的问题是当我尝试在then块中验证是否已抛出异常，并且已经对模拟进行了调用。

请查看以下设置：

class B {
    def b(A a) {
        a.a()
    }
}

class A {
    def a() {
    }
}

def "foo"() {
    given:
    def a = Mock(A)
    a.a() >> { throw new RuntimeException() }
    B b = new B()

    when:
    b.b(a)

    then:
    thrown(RuntimeException)
    1 * a.a()
}

上述测试失败并显示消息：Expected exception java.lang.RuntimeException, but no exception was thrown，但设置模拟的代码显式抛出异常。

有趣的是，如果删除最后一行：1 * a.a()测试通过。在将当前块中的另一个断言组合在一起并没有验证异常时，我没有遇到类似的问题。

任何想法会发生什么？

Answer 1

应按以下方式配置和验证：

@Grab('org.spockframework:spock-core:0.7-groovy-2.0')
@Grab('cglib:cglib-nodep:3.1')

import spock.lang.*

class Test extends Specification {
    def "foo"() {
        given:
        def a = Mock(A)
        B b = new B()

        when:
        b.b(a)

        then:
        thrown(RuntimeException)
        1 * a.a() >> { throw new RuntimeException() }
    }
}


class B {
    def b(A a) {
        a.a()
    }
}

class A {
    def a() {
    }
}

如果您同时模拟和验证交互，则应在where / then块中配置模拟行为。

Spock验证模拟抛出的异常以及模拟交互

1 个答案: