我希望我的.bat脚本（test.bat）创建自己的快捷方式，以便我可以将其复制到我的Windows 8 Startup文件夹中。
我已经编写了这行代码来复制文件，但我还没有找到创建快捷方式的方法，因为你可以看到它只复制脚本。
xcopy "C:\Users\Gabriel\Desktop\test.bat" "C:\Users\Gabriel\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup"
答案 0 :(得分：39)
您可以使用PowerShell命令。将其粘贴在批处理脚本中，然后在%~f0中创建%userprofile%\Start Menu\Programs\Startup的快捷方式：
powershell "$s=(New-Object -COM WScript.Shell).CreateShortcut('%userprofile%\Start Menu\Programs\Startup\%~n0.lnk');$s.TargetPath='%~f0';$s.Save()"
如果您不想使用PowerShell，可以使用mklink创建符号链接。语法：
mklink saveShortcutAs targetOfShortcut
有关完整语法，请参阅控制台窗口中的mklink /?，有关详细信息，请参阅this web page。
在批处理脚本中，执行：
mklink "%userprofile%\Start Menu\Programs\Startup\%~nx0" "%~f0"
创建的快捷方式不是传统的.lnk文件，但它应该可以正常工作。请注意，只有.bat文件与启动文件夹在同一驱动器上运行时，才能使用此选项。此外，显然需要管理员权限才能创建符号链接。
答案 1 :(得分：6)
Rohit Sahu的回答在Windows 10中最适合我.PowerShell解决方案已经运行，但没有出现快捷方式。 JScript解决方案给了我语法错误。我没有尝试mklink，因为我不想搞砸权限。
我希望快捷方式显示在桌面上。 但我还需要设置图标，描述和工作目录。 请注意，MyApp48.bmp是一个48x48像素的图像。 这是我的Rohit解决方案的模式：
@echo off
cd c:\MyApp
echo Set oWS = WScript.CreateObject("WScript.Shell") > CreateShortcut.vbs
echo sLinkFile = "%userprofile%\Desktop\MyApp.lnk" >> CreateShortcut.vbs
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> CreateShortcut.vbs
echo oLink.TargetPath = "C:\MyApp\MyApp.bat" >> CreateShortcut.vbs
echo oLink.WorkingDirectory = "C:\MyApp" >> CreateShortcut.vbs
echo oLink.Description = "My Application" >> CreateShortcut.vbs
echo oLink.IconLocation = "C:\MyApp\MyApp48.bmp" >> CreateShortcut.vbs
echo oLink.Save >> CreateShortcut.vbs
cscript CreateShortcut.vbs
del CreateShortcut.vbs
答案 2 :(得分：5)
最好的方法是运行此批处理文件。 打开记事本并输入： -
@echo off
echo Set oWS = WScript.CreateObject("WScript.Shell") > CreateShortcut.vbs
echo sLinkFile = "GIVETHEPATHOFLINK.lnk" >> CreateShortcut.vbs
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> CreateShortcut.vbs
echo oLink.TargetPath = "GIVETHEPATHOFTARGETFILEYOUWANTTHESHORTCUT" >> CreateShortcut.vbs
echo oLink.Save >> CreateShortcut.vbs
cscript CreateShortcut.vbs
del CreateShortcut.vbs
另存为filename.bat（保存时请注意选择所有文件类型） 在win XP中运作良好。
答案 3 :(得分：4)
link.vbs
set fs = CreateObject("Scripting.FileSystemObject")
set ws = WScript.CreateObject("WScript.Shell")
set arg = Wscript.Arguments
linkFile = arg(0)
set link = ws.CreateShortcut(linkFile)
link.TargetPath = fs.BuildPath(ws.CurrentDirectory, arg(1))
link.Save
命令
C:\dir>link.vbs ..\shortcut.txt.lnk target.txt
答案 4 :(得分：2)
我提供了一个小型混合脚本 [BAT / VBS] 来创建桌面快捷方式。 当然，你可以根据自己的目的修改它。
@echo off
mode con cols=87 lines=5 & color 9B
Title Shortcut Creator for your batch and applications files by Hackoo 2015
Set MyFile=%~f0
Set ShorcutName=HackooTest
(
echo Call Shortcut("%MyFile%","%ShorcutName%"^)
echo ^'**********************************************************************************************^)
echo Sub Shortcut(ApplicationPath,Nom^)
echo Dim objShell,DesktopPath,objShortCut,MyTab
echo Set objShell = CreateObject("WScript.Shell"^)
echo MyTab = Split(ApplicationPath,"\"^)
echo If Nom = "" Then
echo Nom = MyTab(UBound(MyTab^)^)
echo End if
echo DesktopPath = objShell.SpecialFolders("Desktop"^)
echo Set objShortCut = objShell.CreateShortcut(DesktopPath ^& "\" ^& Nom ^& ".lnk"^)
echo objShortCut.TargetPath = Dblquote(ApplicationPath^)
echo ObjShortCut.IconLocation = "Winver.exe,0"
echo objShortCut.Save
echo End Sub
echo ^'**********************************************************************************************
echo ^'Fonction pour ajouter les doubles quotes dans une variable
echo Function DblQuote(Str^)
echo DblQuote = Chr(34^) ^& Str ^& Chr(34^)
echo End Function
echo ^'**********************************************************************************************
) > Shortcutme.vbs
Start /Wait Shortcutme.vbs
Del Shortcutme.vbs
::***************************************Main Batch*******************************************
cls
echo Done and your main batch goes here !
echo i am a test
Pause > Nul
::********************************************************************************************
答案 5 :(得分：2)
Nirsoft的NirCMD也可以从命令行创建快捷方式。 （以及其他功能。）免费，可在此处下载：
http://www.nirsoft.net/utils/nircmd.html
此处有完整说明： http://www.nirsoft.net/utils/nircmd2.html#using（向下滚动到“快捷方式”部分。）
是的，使用nircmd确实意味着您正在使用另一个第三方.exe，但是它可以完成上述大多数解决方案中没有的某些功能（例如，在具有多个图标的dll中选择一个图标＃，分配一个热键，并将快捷方式目标设置为最小或最大化。
尽管看起来上面的shortcutjs.bat解决方案也可以完成大部分操作，但是您需要进一步挖掘以找到如何正确分配这些设置的方法。 Nircmd可能更简单。
答案 6 :(得分：1)
我想提出一个此处未提及的使用.URL文件的解决方案：
set SHRT_LOCA=%userprofile%\Desktop\new_shortcut2.url
set SHRT_DEST=C:\Windows\write.exe
echo [InternetShortcut]> %SHRT_LOCA%
echo URL=file:///%SHRT_DEST%>> %SHRT_LOCA%
echo IconFile=%SHRT_DEST%>> %SHRT_LOCA%
echo IconIndex=0>> %SHRT_LOCA%
注意：
.url文件用于打开网页，但对于任何正确构造的URI来说都可以正常工作.url文件扩展名IconFile和IconIndex是可选的答案 7 :(得分：1)
我创建了一个VB脚本，然后从命令行或Java进程运行它。 在创建快捷方式时，我还尝试捕获错误，以便可以更好地处理错误。
Set oWS = WScript.CreateObject("WScript.Shell")
shortcutLocation = Wscript.Arguments(0)
'error handle shortcut creation
On Error Resume Next
Set oLink = oWS.CreateShortcut(shortcutLocation)
If Err Then WScript.Quit Err.Number
'error handle setting shortcut target
On Error Resume Next
oLink.TargetPath = Wscript.Arguments(1)
If Err Then WScript.Quit Err.Number
'error handle setting start in property
On Error Resume Next
oLink.WorkingDirectory = Wscript.Arguments(2)
If Err Then WScript.Quit Err.Number
'error handle saving shortcut
On Error Resume Next
oLink.Save
If Err Then WScript.Quit Err.Number
我使用以下命令运行脚本：
cscript /b script.vbs shortcutFuturePath targetPath startInProperty
在某些情况下，即使不设置“开始于”属性，也可以使其正常工作。
答案 8 :(得分：1)
为了创建 warp-cli.exe 的快捷方式，我基于 rojo 的 Powershell 命令并添加了 WorkingDirectory、Arguments、IconLocation 并最小化了 WindowStyle 属性。< /p>
powershell "$s=(New-Object -COM WScript.Shell).CreateShortcut('%userprofile%\Start Menu\Programs\Startup\CWarp_DoH.lnk');$s.TargetPath='E:\Program\CloudflareWARP\warp-cli.exe';$s.Arguments='connect';$s.IconLocation='E:\Program\CloudflareWARP\Cloudflare WARP.exe';$s.WorkingDirectory='E:\Program\CloudflareWARP';$s.WindowStyle=7;$s.Save()"
CreateShortcut 的其他 PS 属性：https://stackoverflow.com/a/57547816/4127357