Question

我一直在为我的程序/批处理文件创建快捷方式...... 我想批量做，创建一个VBS文件，因为（至少我认为）批处理不能创建快捷方式......但是因为我不是所有 familiare与VBS编码我根本不知道怎么做。

但我知道我希望它如何。我正在寻找一个代码，我可以将文件名和位置放入其中，并且它可以工作：3 由于我在vbs上的竞争非常残疾，我不会太了解任何事情。

提前致谢：）

Answer 1

我提供了一个小型混合脚本 [BAT / VBS] 来创建桌面快捷方式。因此，此脚本向您展示如何在桌面上创建计算器的快捷方式。

@echo off
mode con cols=87 lines=5 & color 9B
Title Generer le vbscript pour la creation du raccourci sur le bureau by Hackoo
echo Generer le vbscript pour la creation du raccourci
Timeout /T 2 > Nul
(
echo Call Shortcut("c:\windows\system32\calc.exe","Calculatrice"^)
echo ^'**********************************************************************************************^)
echo Sub Shortcut(CheminApplication,Nom^)
echo    Dim objShell,DesktopPath,objShortCut,MyTab
echo    Set objShell = CreateObject("WScript.Shell"^)
echo    MyTab = Split^(CheminApplication,"\"^)
echo    If Nom = "" Then
echo    Nom = MyTab(UBound^(MyTab^)^)
echo    End if
echo    DesktopPath = objShell.SpecialFolders("Desktop"^)
echo    Set objShortCut = objShell.CreateShortcut(DesktopPath ^& "\" ^& Nom ^& ".lnk"^)
echo    objShortCut.TargetPath = Dblquote^(CheminApplication^)
echo    ObjShortCut.IconLocation = "Winver.exe,0"
echo    objShortCut.Save
echo End Sub
echo ^'**********************************************************************************************
echo ^'Fonction pour ajouter les doubles quotes dans une variable
echo Function DblQuote(Str^)
echo    DblQuote = Chr(34^) ^& Str ^& Chr^(34^)
echo End Function
echo ^'**********************************************************************************************
) > Shortcutme.vbs
echo Execution du vbscript pour la creation du raccourci de la calculatrice sur le bureau
Start /Wait Shortcutme.vbs
echo Suppression du Vbscript
Del Shortcutme.vbs
echo Termine
Pause > Nul

Answer 2

详细说明这个答案，让你理解它;

在桌面上制作文本文件并复制/粘贴此文本：

@echo off

set SCRIPT="%TEMP%\%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.vbs"

echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT%
echo sLinkFile = "%USERPROFILE%\Desktop\myshortcut.lnk" >> %SCRIPT%
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT%
echo oLink.TargetPath = "D:\myfile.extension" >> %SCRIPT%
echo oLink.Save >> %SCRIPT%

cscript /nologo %SCRIPT%
del %SCRIPT%

将myshortcut.lnk中的"%USERPROFILE%\Desktop\myshortcut.lnk"更改为您希望快捷方式拥有的名称（例如"%USERPROFILE%\Desktop\iversenFiles.lnk"）。

将"D:\myfile.extension"更改为您希望快捷方式所在的位置（例如"C:\iversen\Documents\iversen.txt"）。

保存文件并将其扩展名从.txt更改为.bat

双击它。

在Bat或VBS中创建快捷方式

2 个答案: