Question

Lisp新手在这里。

我正在阅读Paul Graham的书，ANSI Common Lisp。

第38页是uncompress功能。它需要一对对列表，其中对中的第一项是一个数字，表示应该有多少第二项。例如，解压缩：

((3 a) (2 b) c)

应该产生这个：

(A A A B B C)

我将uncompress函数输入到Lisp解释器（GCL-2.6.2-ANSI）中，然后像这样测试它：

(uncompress '((3 A) B (2 C) (5 D)))

这产生了此错误消息：

Error in IF [or a callee]: Too many arguments.

Fast links are on: do (use-fast-links nil) for debugging
Broken at IF.  Type :H for Help.
 1 (Abort) Return to top level.

以下是uncompress功能。我认为我忠实地输入了书中所写的内容。我测试了每一件，每件都看似正常。说实话，我被困住了。我不知道是什么导致了这个错误。我很感激你的帮助。

(defun uncompress (lst)
   (if (null lst)
       nil
       (let (elt (car lst))
            (rest (uncompress (cdr lst))))
        (if (consp elt)
            (append (apply #'list-of elt)
                    rest)
            (cons elt rest))))

(defun list-of (n elt)
   (if (zerop n)
       nil
       (cons elt (list-of (- n 1) elt))))

Answer 1

如果使用编辑器缩进工具，代码如下所示：

(defun uncompress (lst)
  (if (null lst)
      nil
    (let (elt (car lst))
      (rest (uncompress (cdr lst))))
    (if (consp elt)
        (append (apply #'list-of elt)
                rest)
      (cons elt rest))))

这样可以更容易发现此错误。从语法上讲，这是错误的，因为IF不会超过三种形式。

(defun uncompress (lst)
  (if (null lst)   ; the IF has four subforms, one too many
      nil
    (let (elt (car lst))  ;<- variables ELT and CAR? Makes no sense
      (rest (uncompress (cdr lst))))   ; <- not using the result?
    (if (consp elt)    ; <- fourth form in IF? Does not make sense.
        (append (apply #'list-of elt)
                rest)
      (cons elt rest))))

在Common Lisp中，IF和LET都是具有内置语法的特殊运算符。

在Lisp中，LET的语法通常是：

let ({var | (var [init-form])}*) form* => result*

在Common Lisp中，可以在LET的正文形式之上添加声明：

let ({var | (var [init-form])}*) declaration* form* => result*

Common Lisp中IF的语法是：

if test-form then-form [else-form] => result*

<强>压痕

通常，手动缩进Lisp代码并不是一个好主意。让编辑器或IDE执行此操作。确保所有代码都正确缩进。

如果您有语法问题：首先重新缩进表达式 - ＆gt;这可以确保代码正确缩进，然后使查找问题更容易。接下来编译代码并读取编译器错误消息。 Common Lisp有很好的编译器，有些还有很好的错误报告。

代码

无论如何代码都不是很好：它使用递归，其中存在高阶函数或LOOP会更好

此版本同时包含：高阶MAPCAN和LOOP：

(defun uncompress (list)
  (mapcan #'expand-item list))

(defun expand-item (item)
  (typecase item
    (atom (list item))
    (cons (destructuring-bind (n element) item
              (loop repeat n collect element)))))

Answer 2

您有最典型的常见lisp语法错误：错误地使用括号！

这是正确的版本：

(defun uncompress (lst)
  (if (null lst)
      nil
      (let ((elt (car lst))
            (rest (uncompress (cdr lst))))
        (if (consp elt)
            (append (apply #'list-of elt)
                    rest)
            (cons elt rest)))))

由于在没有使用专门编辑器时这些错误很常见，我建议您使用Emacs或Vim等编辑器来编辑程序。

Common Lisp：在Paul Graham的书中无法获得解压缩功能

2 个答案: