Question

您好我正在寻找使用F＃读取固定宽度文本文件的最佳方法。该文件将是纯文本，从一行到几千行，宽约1000个字符。每行包含大约50个字段，每个字段具有不同的长度。我最初的想法是有类似下面的内容

type MyRecord = {
    Name : string
    Address : string
    Postcode : string
    Tel : string
}

let format = [
    (0,10)
    (10,50)
    (50,7)
    (57,20)
]

并逐个读取每一行，按格式元组分配每个字段（第一项是起始字符，第二项是宽字符数）。

任何指针都会受到赞赏。

Answer 1

最难的部分可能是根据列格式拆分一行。它可以这样做：

let splitLine format (line : string) =
    format |> List.map (fun (index, length) -> line.Substring(index, length))

此函数的类型为(int * int) list -> string -> string list。换句话说，format是(int * int) list。这与您的format列表完全对应。 line参数是string，函数返回string list。

您可以映射这样的行列表：

let result = lines |> List.map (splitLine format)

您还可以使用Seq.map或Array.map，具体取决于lines的定义方式。这样的result将是string list list，您现在可以在此类列表上进行映射以生成MyRecord list。

您可以使用File.ReadLines从文件中获取延迟评估的字符串序列。

请注意，以上仅是可能解决方案的概述。我遗漏了边界检查，错误处理等。上面的代码可能包含一个错误。

Answer 2

50个字段的记录有点笨拙，因此允许动态生成数据结构的替代方法可能更为可取（例如。System.Data.DataRow）。

如果它必须是一个记录，你至少可以保留每个记录字段的手动分配，并在Reflection的帮助下填充它。这个技巧依赖于定义的字段顺序。我假设固定宽度的每一列代表一个记录字段，因此暗示了起始索引。

open Microsoft.FSharp.Reflection

type MyRecord = {
    Name : string
    Address : string
    City : string
    Postcode : string
    Tel : string } with
    static member CreateFromFixedWidth format (line : string) =
        let fields =
            format 
            |> List.fold (fun (index, acc) length ->
                let str = line.[index .. index + length - 1].Trim()
                index + length, box str :: acc )
                (0, [])
            |> snd
            |> List.rev
            |> List.toArray
        FSharpValue.MakeRecord(
            typeof<MyRecord>,
            fields ) :?> MyRecord

示例数据：

"Postman Pat     " +
"Farringdon Road " +
"London          " +
"EC1A 1BB"         +
"+44 20 7946 0813"
|> MyRecord.CreateFromFixedWidth [16; 16; 16; 8; 16]
// val it : MyRecord = {Name = "Postman Pat";
//                      Address = "Farringdon Road";
//                      City = "London";
//                      Postcode = "EC1A 1BB";
//                      Tel = "+44 20 7946 0813";}

Answer 3

这是一个专注于每个字段的自定义验证和错误处理的解决方案。对于仅包含数字数据的数据文件，这可能有点过分了！

首先，对于这些类型的事情，我喜欢在Microsoft.VisualBasic.dll中使用解析器，因为它已经可用，而不使用NuGet。

对于每一行，我们都可以返回字段数组和行号（用于错误报告）

#r "Microsoft.VisualBasic.dll"

// for each row, return the line number and the fields
let parserReadAllFields fieldWidths textReader =
    let parser = new Microsoft.VisualBasic.FileIO.TextFieldParser(reader=textReader)
    parser.SetFieldWidths fieldWidths 
    parser.TextFieldType <- Microsoft.VisualBasic.FileIO.FieldType.FixedWidth
    seq {while not parser.EndOfData do 
           yield parser.LineNumber,parser.ReadFields() }

接下来，我们需要一个小错误处理库（有关详细信息，请参阅http://fsharpforfunandprofit.com/rop/）

type Result<'a> = 
    | Success of 'a
    | Failure of string list

module Result =

    let succeedR x = 
        Success x

    let failR err = 
        Failure [err]

    let mapR f xR = 
        match xR with
        | Success a -> Success (f a)
        | Failure errs -> Failure errs 

    let applyR fR xR = 
        match fR,xR with
        | Success f,Success x -> Success (f x)
        | Failure errs,Success _ -> Failure errs 
        | Success _,Failure errs -> Failure errs 
        | Failure errs1, Failure errs2 -> Failure (errs1 @ errs2)

然后定义您的域模型。在这种情况下，它是记录类型，文件中的每个字段都有一个字段。

type MyRecord = 
    {id:int; name:string; description:string}

然后您可以定义特定于域的解析代码。对于每个字段，我创建了一个验证函数（validateId，validateName等）。不需要验证的字段可以传递原始数据（validateDescription）。

在fieldsToRecord中，使用应用样式（<!>和<*>）合并各个字段。有关详情，请参阅http://fsharpforfunandprofit.com/posts/elevated-world-3/#validation。

最后，readRecords将每个输入行映射到记录结果，并仅选择成功的行。失败的文件将写入handleResult中的日志。

module MyFileParser = 
    open Result

    let createRecord id name description =
        {id=id; name=name; description=description}

    let validateId (lineNo:int64) (fields:string[]) = 
        let rawId = fields.[0]
        match System.Int32.TryParse(rawId) with
        | true, id -> succeedR id
        | false, _ -> failR (sprintf "[%i] Can't parse id '%s'" lineNo rawId)

    let validateName (lineNo:int64) (fields:string[]) = 
        let rawName = fields.[1]
        if System.String.IsNullOrWhiteSpace rawName then
            failR (sprintf "[%i] Name cannot be blank" lineNo )
        else
            succeedR rawName

    let validateDescription (lineNo:int64) (fields:string[]) = 
        let rawDescription = fields.[2]
        succeedR rawDescription // no validation

    let fieldsToRecord (lineNo,fields) =
        let (<!>) = mapR    
        let (<*>) = applyR
        let validatedId = validateId lineNo fields
        let validatedName = validateName lineNo fields
        let validatedDescription = validateDescription lineNo fields
        createRecord <!> validatedId <*> validatedName <*> validatedDescription 

    /// print any errors and only return good results
    let handleResult result = 
        match result with
        | Success record -> Some record 
        | Failure errs -> printfn "ERRORS %A" errs; None

    /// return a sequence of records
    let readRecords parserOutput = 
        parserOutput 
        |> Seq.map fieldsToRecord 
        |> Seq.choose handleResult

以下是实践中解析的一个示例：

// Set up some sample text
let text = """01name1description1
02name2description2
xxname3badid-------
yy     badidandname
"""

// create a low-level parser
let textReader = new System.IO.StringReader(text)
let fieldWidths = [| 2; 5; 11 |]
let parserOutput = parserReadAllFields fieldWidths textReader 

// convert to records in my domain
let records = 
    parserOutput 
    |> MyFileParser.readRecords 
    |> Seq.iter (printfn "RECORD %A")  // print each record

输出如下：

RECORD {id = 1;
 name = "name1";
 description = "description";}
RECORD {id = 2;
 name = "name2";
 description = "description";}
ERRORS ["[3] Can't parse id 'xx'"]
ERRORS ["[4] Can't parse id 'yy'"; "[4] Name cannot be blank"]

这绝不是解析文件的最有效方法（我认为NuGet上有一些可以在解析时进行验证的CSV解析库）但它确实显示了如何完全控制验证和错误处理如果你需要它。

F＃读取固定宽度文本文件

3 个答案: