Question

让Delphi应用程序运行DWS脚本。 Delphi应用程序公开了一个对象实例，让它将它称为脚本，并将其称为＃34; MyApplication＆＃34;。公开的对象有一个方法，其中一个参数是一个过程。

从根本上说，目标是让Delphi方法进行一些计算，并在回调程序完成后停止计算。回调过程在脚本内部。

我已经通过将回调函数的名称作为字符串传递来实现这一点。它工作得很好，除了在脚本编译时没有进行类型检查。我想传递一个实际的过程，以便脚本编译器可以在编译时捕获任何错误。

怎么做？

为了帮助读者理解我的意思，我展示了一些 - 不工作 - 代码：

首先是Delphi方面的简化版本：

Interface
type
    TAppCheckProc = procedure (var Done : Boolean);

TMyApplication = class(TPersistent)
published
    procedure Demo(CheckProc : TAppCheckProc);
end;

Implementation

TMyApplication.Demo(CheckProc : TAppCheckProc);
var
    Done : Boolean;
begin
    Done := FALSE;
    while not Done do begin
        // Some more code here...
        CheckProc(Done);
    end;
end;

其次，在脚本方面我有这个（还有简化）：

procedure CheckProc(
    var Done : Boolean);
var
    Value : Integer;
begin
    DigitalIO.DataIn(1, Value);
    Done := (Value and 8) = 0;
end;

procedure Test;
begin
    MyApplication.Demo(CheckProc);
end;

可能应该以不同方式声明Demo方法参数，并且应该以不同方式调用它们。这就是问题......

编辑：删除了额外的Tag参数（简化代码时出错，这不是问题）。

Answer 1

我把它放在一起很快就可以了。当回调参数不正确时，它会产生编译错误。您需要创建一个委托并将其用作类型。

使用独立功能的示例

dwsUnit是用于自定义Delphi方法的TdwsUnit。

procedure TMainForm.FormCreate(Sender: TObject);
var
  delegate: TdwsDelegate;
  func: TdwsFunction;
  parm: TdwsParameter;
begin
  // Create a delegate
  delegate := dwsUnit.Delegates.Add;
  delegate.Name := 'TAppCheckProc';
  parm := delegate.Parameters.Add;
  parm.Name := 'Done';
  parm.DataType := 'Boolean';
  parm.IsVarParam := True;

  // Create our function and link it to the event handler
  func := dwsUnit.Functions.Add;
  func.Name := 'Demo';
  func.OnEval := dwsUnitFunctionsDemoEval;
  parm := func.Parameters.Add;
  parm.Name := 'CheckProc';
  parm.DataType := 'TAppCheckProc';
end;

我用来测试它的脚本如下：

procedure CheckProc(
    var Done : Boolean);
begin
  if Done then
    SayHello('World');
end;

Demo(CheckProc);

如果我将参数从布尔值更改为整数，我会在脚本上遇到编译错误。

我的完整性事件处理程序如下所示：

procedure TMainForm.dwsUnitFunctionsDemoEval(info: TProgramInfo);
begin
  info.Vars['CheckProc'].Call([True]);
end;

使用类

的示例

如果你想使用类，那么代码会略有不同。假设您正在使用CustomClasses演示并想要使用TEarth类，那么这将是创建方法和委托的代码。

procedure TMainForm.FormCreate(Sender: TObject);
var
  delegate: TdwsDelegate;
  method: TdwsMethod;
  parm: TdwsParameter;
begin
  // Create a delegate
  delegate := dwsUnit.Delegates.Add;
  delegate.Name := 'TAppCheckProc';
  parm := delegate.Parameters.Add;
  parm.Name := 'Done';
  parm.DataType := 'Boolean';
  parm.IsVarParam := True;

  // Create our method and link it to the event handler
  method := TdwsClass(dwsUnit.Classes.Symbols['TEarth']).Methods.Add;
  method.Name := 'Demo';
  method.OnEval := dwsUnitFunctionsDemoEval;
  parm := method.Parameters.Add;
  parm.Name := 'CheckProc';
  parm.DataType := 'TAppCheckProc';
end;

使用它的脚本是：

procedure CheckProc(
    var Done : Boolean);
begin
  if Done then
    PrintLn('Called with true')
  else
    PrintLn('Called with false');
end;

var earth: TEarth;
earth:=TEarth.Create;
earth.Demo(CheckProc);

事件处理程序如下：

procedure TMainForm.dwsUnitFunctionsDemoEval(info: TProgramInfo; ExtObject:
    TObject);
begin
  info.Vars['CheckProc'].Call([True]);
end;

与独立版本一样，更改脚本参数类型会产生“编译器”错误。

正如SpeedFreak在评论中指出的那样。您也可以通过IDE设计器而不是代码执行此操作。

如何声明从具有过程类型参数的脚本调用的Delphi对象的方法

1 个答案:

使用独立功能的示例

使用类