手动更新/重新绘制项目

Question

我的问题与Calendar有关，但可以应用于每个QML视觉Item。有没有办法手动重绘Item？

在我的情况下，我有Calendar个自定义内容（单元格26中的小橙色数字）：

要做到这一点，我使用样式：

import QtQuick 2.5
import QtQuick.Window 2.2
import QtQuick.Controls 1.2
import QtQuick.Controls.Styles 1.2

Window {
    width: 300
    height: 300
    id: window
    Calendar {
        id: calendar
        anchors.fill: parent
        property var dataArr: {26: 7}
        style: CalendarStyle {
            dayDelegate: Rectangle {
                Label {
                    text: styleData.date.getDate()
                    anchors.centerIn: parent
                }
                Label {
                    font.pixelSize: 8
                    anchors.right: parent.right
                    anchors.bottom: parent.bottom
                    width: 12
                    height: 10
                    horizontalAlignment: Text.AlignHCenter
                    text: calendar.dataArr[styleData.date.getDate()] ? calendar.dataArr[styleData.date.getDate()] : ""
                    color: "orange"
                }
            }
        }
        Component.onCompleted: {
            calendar.dataArr[26] = 8; //that doesn't work
        }
    }
}

使用静态数组可以正常工作，但如果我更改数据数组中的值，则不会更新单元格。如何强制Calendar更新？

Answer 1

根据this，以这种方式不会为var触发绑定更新。他们在示例之后提供了解决方案。在此处应用：

property var dataArr: new Object( {26: 7} )
...
Component.onCompleted: {
   dataArr = new Object( {26: 8} )
}