Question

如何检查批处理文件中的变量是否包含特殊字符？例如，如果我的变量包含文件名，那么文件名不应包含\/ < > | : * " ?这些字符。

@echo off
set param="XXX"
echo %param%| findstr /r "^[^\\/?%*:|"<>\.]*$">nul

if %errorlevel% equ 0 goto :next
echo "Invalid Attribute"

:next
echo correct

我使用此链接作为参考regex for validating folder name & file name

Answer 1

您无法使用echo %param%| findstr /r ...，也无法使用echo !param!| findstr /r ...。有关如何解析和处理管道的更多信息，请查看此问题和答案：Why does delayed expansion fail when inside a piped block of code。

使用辅助（临时）文件，如下所示：

@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
:testloop
  set "param="
  set /P "param=string to test (hit <Enter> to end)> "
  if not defined param goto :endtest
  >"%temp%\33605517.txt" echo(!param!

  rem next line for debugging purposes
  for /F "usebackq delims=" %%G in ("%temp%\33605517.txt") do set "_marap=%%G"

  findstr /r ".*[<>:\"\"/\\|?*%%].*" "%temp%\33605517.txt" >nul 

  if %errorlevel% equ 0 (
    echo !errorlevel! Invalid !param! [!_marap!]
  ) else (
    echo !errorlevel! correct !param! [!_marap!]
  )
  goto :testloop
:endtest
ENDLOCAL
goto :eof

.*[<>:\"\"/\\|?*%%].*正则表达解释：

.* - 字符串前面任何字符出现零次或多次;
[<>:\"\"/\\|?*%%]保留字符集中的任何一个字符：
- <（小于）;
- >（大于）;
- :（冒号）;
- "（双引号）转义为\"\"（findstr和批量解析器）;
- /（正斜杠）;
- \（反斜杠）转义为\\（findstr）;
- |（垂直条或竖线）;
- ?（问号）;
- *（星号）;
- %（百分号）转义（对于批量解析器）为%%;事实上，% is not reserved for NTFS file system但需要在纯cmd和/或批处理脚本中进行特殊转义;
.* - 字符串末尾出现零个或多个字符。

以下是关于SO的一些问题的更多链接以及Aacini，DBenham，Jeb（以及其他人）的详尽答案。令人兴奋，迷人的阅读...

<强>输出：

string to test (hit <Enter> to end)> n<m
0 Invalid n<m [n<m]
string to test (hit <Enter> to end)> n>m
0 Invalid n>m [n>m]
string to test (hit <Enter> to end)> n:m
0 Invalid n:m [n:m]
string to test (hit <Enter> to end)> n/m
0 Invalid n/m [n/m]
string to test (hit <Enter> to end)> n\m
0 Invalid n\m [n\m]
string to test (hit <Enter> to end)> n|m
0 Invalid n|m [n|m]
string to test (hit <Enter> to end)> n?m
0 Invalid n?m [n?m]
string to test (hit <Enter> to end)> n*m
0 Invalid n*m [n*m]
string to test (hit <Enter> to end)> n"m
0 Invalid n"m [n"m]
string to test (hit <Enter> to end)> nm
1 correct nm [nm]
string to test (hit <Enter> to end)> nm.gat
1 correct nm.gat [nm.gat]
string to test (hit <Enter> to end)> n%m.gat
0 Invalid n%m.gat [n%m.gat]
string to test (hit <Enter> to end)>

Answer 2

您可以将您的findstr行更改为

set "param=Test < string"

cmd /v:on /c echo(^^!param^^! | findstr /r "^[^\\/?%%*:|<>\.\"]*$^" > nul

if %errorlevel% equ 0 ( 
echo OK
) ELSE (
  echo Invalid, special character found
)

这是有效的，因为param将在子cmd.exe进程中扩展，并且延迟扩展如果启用或不启用延迟扩展，则不重要，线路始终有效我改变了正则表达式，因为搜索引用本身有点讨厌。

如何检查变量是否包含批处理文件中的特殊字符

2 个答案: