Question

我有以下脚本应该设置环境变量%NUMBER%：

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

SET processed=0

IF "%~1"=="latest" (
    CALL :LATEST_BUILD_NUMBER %~2
    ECHO "->%build_number% RETURNS NO DATA"
    ECHO "->!build_number! GIVES THE BUILD NUMBER BACK"
    CALL :SET_ENVIRONMENT_VARIABLE  !build_number!
    SET processed=1
)

:END
    ENDLOCAL
    ECHO ON
    @EXIT /B 0

:SET_ENVIRONMENT_VARIABLE
    ECHO SET "NUMBER=%~1"
    SET "NUMBER=%~1"
    @EXIT /B 0

:LATEST_BUILD_NUMBER
    REM CALCULATE THE BUILDNUMBER, NOW JUST SET IT
    set build_number=589
    EXIT /B 0

当我在命令提示符窗口中运行此代码并执行NUMBER变量的回显时，它不会在控制台窗口中设置。

d:\> ECHO %NUMBER%
%NUMBER%

我该如何正确地做到这一点？

Answer 1

每个setlocal都会创建一个新的变量范围此范围将使用endlocal销毁，或通过退出批处理文件隐式显示。

您必须在范围生命周期内保护变量（通常称为endlocal barrier）。

在被叫函数中，ENDLOCAL外SETLOCAL不可能（不是不可能，只有advanced technics）。
所以你必须修改你的代码。

@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion

SET processed=0
SET build_number=0

IF "%~1"=="latest" (
    CALL :LATEST_BUILD_NUMBER %~2
    ECHO -^>%build_number% RETURNS NO DATA
    ECHO -^>!build_number! GIVES THE BUILD NUMBER BACK
    REM *** CALL :SET_ENVIRONMENT_VARIABLE !build_number!
    SET processed=1
)

:END
(
  ENDLOCAL
  set "number=%build_number%"
  EXIT /B 0
)
...

诀窍是使用括号构建一个ENDLOCAL-Block，因为在解析块时会评估百分比扩展，因此在ENDLOCAL执行后该值将可用。

设置启用了延迟扩展的环境变量

1 个答案: