Question

我有一些特殊字符的URL，我想替换它们，我使用xslt 1.0，所以我写的代码如下。

<xsl:template name="string-replace-all"> 
        <xsl:param name="text"/> 
        <xsl:param name="replace"/> 
        <xsl:param name="by"/> 
        <xsl:choose> 
            <xsl:when test="contains($text,$replace)"> 
                <xsl:value-of select="substring-before($text,$replace)"/> 
                <xsl:value-of select="$by"/> 
                <xsl:call-template name="string-replace-all"> 
                    <xsl:with-param name="text" select="substring-after($text,$replace)"/> 
                    <xsl:with-param name="replace" select="$replace"/> 
                    <xsl:with-param name="by" select="$by"/> 
                </xsl:call-template> 
            </xsl:when> 
    <xsl:otherwise> 
      <xsl:value-of select="$text"/> 
    </xsl:otherwise> 
  </xsl:choose> 
</xsl:template>

并且这样打电话：

<td class="ms-vb">
            <xsl:variable name="link">
            <xsl:call-template name="string-replace-all"> 
                <xsl:with-param name="text" select="@FileRef"/> 
                <xsl:with-param name="replace" select="'&#39;'"/> 
                <xsl:with-param name="by" select="'%27'"/> 
            </xsl:call-template> 
            </xsl:variable>-->
                <a target="_blank" href="@link" ><xsl:value-of select="@New_x0020_Doc_x0020_Title" disable-output-escaping="yes" /></a>
            </td>

我收到错误“webpart无法显示”。任何人都可以在这里建议我做错了什么？

Answer 1

提供的“替换”模板正在正常工作。

要确认这一点，请使用以下转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/*">
        <xsl:variable name="link">
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="@FileRef"/>
                <xsl:with-param name="replace">'</xsl:with-param>
                <xsl:with-param name="by" select="'%27'"/>
            </xsl:call-template>
        </xsl:variable>

        "<xsl:value-of select="$link"/>"
    </xsl:template>

    <xsl:template name="string-replace-all">
        <xsl:param name="text"/>
        <xsl:param name="replace"/>
        <xsl:param name="by"/>
        <xsl:choose>
            <xsl:when test="contains($text,$replace)">
                <xsl:value-of select="substring-before($text,$replace)"/>
                <xsl:value-of select="$by"/>
                <xsl:call-template name="string-replace-all">
                    <xsl:with-param name="text" select="substring-after($text,$replace)"/>
                    <xsl:with-param name="replace" select="$replace"/>
                    <xsl:with-param name="by" select="$by"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$text"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

在此XML文档上应用转换时：

<t FileRef="Abc'Xyz'Tuv"/>

产生了想要的正确结果：

"Abc%27Xyz%27Tuv"

问题可能在于您指定replace参数的方式（表达式中的撇号数量不均匀）：

而不是：

<xsl:with-param name="replace" select="'&#39;'"/>

使用：

<xsl:with-param name="replace">'</xsl:with-param>

xslt 1.0替换不起作用

1 个答案: