如何在CheckedListBox vb.net

Question

基本上我有一个选中的清单框，其中的每个项目都有相应的价格。我如何编码以便

1）当选择其中一个项目时，相关价格会存储在代码中的某个位置，并且

2）然后我如何将这些价格加起来（例如，如果已经检查了几个项目，我想将价格加起来并在文本框中显示总数）。

我在＃34; Visual Studio Express for desktop＆＃34;所以基本上是vb.net

Answer 1

这是一个概念性示例，我在Window窗体项目中使用Console.WriteLine，其中输出显示在Visual Studio的输出窗口中。取自following article我写了一段时间，并在此适应了协助。

一个CheckedListBox，一个Button

Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim dt As New DataTable
        dt.Columns.Add(New DataColumn With {.ColumnName = "Identifier",
                                                    .DataType = GetType(Int32),
                                                    .AutoIncrement = True,
                                                    .AutoIncrementStep = 100,
                                                    .AutoIncrementSeed = 100})

        dt.Columns.Add(New DataColumn With {.ColumnName = "ItemName",
                                            .DataType = GetType(String)})

        dt.Columns.Add(New DataColumn With {.ColumnName = "Cost",
                                            .DataType = GetType(Decimal)})

        dt.Columns.Add(New DataColumn With {.ColumnName = "ExtraData",
                                            .DataType = GetType(String)})

        dt.Rows.Add(New Object() {Nothing, "One", 10.99D, "Extra 1"})
        dt.Rows.Add(New Object() {Nothing, "Two", 7D, "Extra 2"})
        dt.Rows.Add(New Object() {Nothing, "Three", 5.99D, "Extra 3"})
        dt.Rows.Add(New Object() {Nothing, "Four", 1.34D, "Extra 4"})
        dt.Rows.Add(New Object() {Nothing, "Five", 45.65D, "Extra 5"})

        clbCheckedListBox.DataSource = dt
        clbCheckedListBox.DisplayMember = "ItemName"

    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        If clbCheckedListBox.CheckedItems.Count > 0 Then
            For Each drv As DataRowView In clbCheckedListBox.CheckedItems
                Console.WriteLine("{0} - {1}", drv.Row.Field(Of String)("ItemName"), drv.Row.Field(Of Decimal)("Cost"))
            Next
            Dim total As Decimal = clbCheckedListBox.CheckedItems.Cast(Of DataRowView).Select(Function(view) view.Row.Field(Of Decimal)("Cost")).Sum
            Console.WriteLine(total)
        End If
    End Sub
End Class