Question

我定义了以下类型（从代码中简化）：

type Polynomial<'a when 'a :(static member public Zero : 'a) 
                and 'a: (static member (+): 'a*'a -> 'a) 
                and 'a : (static member (*): 'a*'a -> 'a) >  =
    | Polynomial of 'a list
    with 
    static member inline (+) (x: Polynomial<'a> , y : Polynomial<'a>) : Polynomial<'a>= 
        match x,y with
        |Polynomial xlist, Polynomial ylist ->
            let longer, shorter = 
                if xlist.Length> ylist.Length then xlist, ylist
                else ylist, xlist
            let shorterExtended = List.append shorter (List.init (longer.Length - shorter.Length) (fun _ -> LanguagePrimitives.GenericZero<'a>))
            List.map2 (+) longer shorterExtended |> Polynomial

当我建立时，我收到警告：

警告FS0193：类型参数缺少约束'when（^ a或^？23604）:( static＆gt; member（+）：^ a * ^？23604 - ＆gt; ^？23605）'

在最后一行的“更长”一词。据我所知，它应该能够推断它总是添加'a'的两个成员。我怎么能摆脱这个？

Answer 1

这是一个有趣的问题，使用let绑定函数而不是静态成员似乎不会触发相同的警告。据推测，在绑定和成员函数中静态类型参数的分辨率之间存在差异。

module PolyAdder =
    let inline addPoly x y = 
        match x,y with
        |Polynomial xlist, Polynomial ylist ->
            let (longer : ^a list), (shorter : ^a list) = 
                if xlist.Length > ylist.Length then xlist, ylist
                else ylist, xlist
            let shorterExtended : ^a list = shorter @ (List.init (longer.Length - shorter.Length) (fun _ -> LanguagePrimitives.GenericZero< ^a >))
            // no warning here!
            List.map2 (+) longer shorterExtended |> Polynomial

然后，您可以使用+运算符基于上面的let bound函数扩展Polynomial：

type Polynomial with
    static member inline (+) (x, y) = PolyAdder.addPoly x y

仍然没有警告，+操作员正常工作

let poly1 = [1; 2; 5; 6; 8] |> Polynomial
let poly2 = [7; 1; 2; 5;] |> Polynomial
let polyAdded = poly1 + poly2

类型推断在具有静态成员约束的泛型类型上失败

1 个答案: