Question

假设我有两条记录： Person 和 Animal 。每条记录都在一个单独的包中。

包裹人员：

with animals;
use animals;

package persons is 

    type person is record
     ...
     animalref: animalPOINTER;
     ...
    end record;

    type personPOINTER is access person;

end persons;

包装动物：

with persons;
use persons;

package animals is 
    type animal is record
     ...
     ownerref:  personPOINTER;
     ...
    end record;

    type animalPOINTER is access animal;

end animals;

我这里有循环单元依赖，编译器会产生致命错误。

有没有人有解决此类问题的模式？

谢谢！

Answer 1

您需要limited with，这是为解决此问题而引入的。请参阅Rationale for Ada 2005, section 4.2。

Animals和Persons是对称的（我的编辑器调整了布局和外壳;我为每个添加了一个记录组件，因此下面的演示程序可以打印一些东西）：

limited with Animals;
package Persons is

   --  One of the few things you can do with an incomplete type, which
   --  is what Animals.Animal is in the limited view of Animals, is to
   --  declare an access to it.
   type AnimalPOINTER is access Animals.Animal;

   type Person is record
      Name : Character;
      Animalref : AnimalPOINTER;
   end record;

end Persons;

limited with Persons;
package Animals is

   type PersonPOINTER is access Persons.Person;

   type Animal is record
      Name : Character;
      Ownerref : PersonPOINTER;
   end record;

end Animals;

演示程序具有Animals和Persons的完整视图。这个例子非常笨拙;您可以通过向Animals和Persons添加子程序来更好地整理内容。请注意Animals的正文可以（并且必须）with Persons;，如果它需要使用Persons中的任何内容。

with Ada.Text_IO; use Ada.Text_IO;
with Animals;
with Persons;
procedure Animals_And_Persons is
   A : Persons.animalPOINTER := new Animals.Animal;
   P : Animals.PersonPOINTER := new Persons.Person;
begin
   A.all := (Name => 'a', Ownerref => P);
   P.all := (Name => 'p', Animalref => A);
   Put_Line (P.Name & " owns " & P.Animalref.Name);
   Put_Line (A.Name & " is owned by " & A.Ownerref.Name);
end Animals_And_Persons;

编译和运行时给出

$ ./animals_and_persons 
p owns a
a is owned by p

阿达：如何解决＆＃34;循环单位依赖＆＃34;？

1 个答案: