Question

在F＃中，我可以在不定义类的情况下表示受限制的类型吗？假设我想表示第一个除以第二个数字的所有数字对。

在C＃中我能做到：

class PairDivides
{
    int a {get;private set;}
    int b {get;private set;}

    PairDivides(int first, int second)
    {
        if (a % b != 0)
        {
            throw new Exception();
        }

        this.a = first;
        this.b = second;
    }
}

现在无法创建一个PairDivides实例b没有划分a ...

这可以仅使用功能构造（记录，区分联合，可能是活动模式等）在F＃中完成吗？

我希望能够创建和接收类似这些对的东西，确保它们构造正确。

Answer 1

您可以将类型设为私有。唯一的缺点是您需要提供访问数据的功能：

module Pairs =
    type PairDivides = private { a: int; b: int }

    let createPairDivides a b =
        match a % b with
        | 0 -> Some { PairDivides.a = a ; b = b }
        | _ -> None

    let print div =
        printfn "{%d %d}" div.a div.b

    let tryPrint div =
        match div with
        | Some a -> print a
        | None -> printfn "None"

let a = Pairs.createPairDivides 2 2

let b = a.Value

// This is inaccessible: b.a

Pairs.createPairDivides 2 2 |> Pairs.tryPrint
Pairs.createPairDivides 2 3 |> Pairs.tryPrint

通过提供创建对的功能，以及根据需要使用或从中提取的功能，您完全消除了创建无效对的能力（您将获得None而不是错误的对）不使用例外。

缺点是您需要提供从对中提取值的机制，因为在当前模块外部使用时，类型现在无法访问。

话虽如此，通过课程做到这一点并没有错。如果您愿意，可以通过创建课程来获得相同级别的强制执行：

type PairDivides private (a,b) =
    member __.A = a
    member __.B = b

    static member Create a b =
        match a % b with
        | 0 -> Some(PairDivides(a,b))
        | _ -> None


PairDivides.Create 2 2 |> printfn "%A"
PairDivides.Create 2 3 |> printfn "%A"

在不使用类的情况下表示受限类型

1 个答案: