Question

好的，当我按下一个特定的按钮时，我想遍历所有表格，然后用标签'TESTING'找到每个表格中的每个控件。如果tag ='TESTING'，那么我想将对象的标题更改为'abc123'。

标签为'TESTING'的唯一对象将是标签，因此它们将具有标题属性。

到目前为止，我将此作为功能：

Public Function changelabel()

On Error Resume Next
Dim obj As AccessObject, dbs As Object
Dim ctrl as Control

Set dbs = Application.CurrentProject

For Each obj In dbs.AllForms
DoCmd.OpenForm obj.Name, acDesign
    For Each ctrl In Me.Controls
        If ctrl.Tag = "TESTING" Then
        ctrl.Caption = "abc123"
        End If

        Next ctrl

Next obj

End Function

然后这作为按钮代码：

Public Sub TestButton_Click()
Call changelabel
End Sub

因此它执行第一个for循环并正确打开设计视图中的所有表单。问题在于第二个for循环。标签属性为“TESTING”的标签标题均未更改为“abc123”。

那么我需要做些什么才能让第二个for循环工作？

Answer 1

像这样的东西

Public Function changelabel()

Dim f As Form
Dim i As Integer
Dim c As Control

For i = 0 To CurrentProject.AllForms.Count - 1
    If Not CurrentProject.AllForms(i).IsLoaded Then
        DoCmd.OpenForm CurrentProject.AllForms(i).Name, acDesign
    End If
    Set f = Forms(i)

    For Each c In f.Controls
        If c.Tag = "TESTING" Then
            c.Caption = "TESTING"
        End If
    Next c
Next i


End Function

你需要添加一些内容来设置用于什么的对象等等。

Answer 2

    Public Sub GetForms()
    Dim oForm As Form
    Dim nItem As Long
    Dim bIsLoaded As Boolean
    For nItem = 0 To CurrentProject.AllForms.Count - 1
        bIsLoaded = CurrentProject.AllForms(nItem).IsLoaded
        If Not bIsLoaded Then
            On Error Resume Next
            DoCmd.OpenForm CurrentProject.AllForms(nItem).NAME, acDesign
        End If
        Set oForm = Forms(CurrentProject.AllForms(nItem).NAME)
        GetControls oForm
        If Not bIsLoaded Then
            On Error Resume Next
            DoCmd.Close acForm, oForm.NAME
        End If
    Next
End Sub

Sub GetControls(ByVal oForm As Form)
    Dim oCtrl As Control
    Dim cCtrlType, cCtrlCaption As String
    For Each oCtrl In oForm.Controls
        If oCtrl.ControlType = acSubform Then Call GetControls(oCtrl.Form)
        Select Case oCtrl.ControlType
            Case acLabel: cCtrlType = "label": cCtrlCaption = oCtrl.Caption
            Case acCommandButton: cCtrlType = "button": cCtrlCaption = oCtrl.Caption
            Case acTextBox: cCtrlType = "textbox": cCtrlCaption = oCtrl.Properties("DataSheetCaption")
            Case Else: cCtrlType = ""
        End Select
        If cCtrlType <> "" Then
            Debug.Print oForm.NAME
            Debug.Print oCtrl.NAME
            Debug.Print cCtrlType
            Debug.Print cCtrlCaption
        End If
    Next
End Sub

Microsoft Access - 遍历每个表单上的所有表单和控件

2 个答案: