Question

:KEY参数包含在Common Lisp附带的一些函数中。我找到的所有描述都没有用，:KEY很难在搜索引擎中搜索，因为＆＃34;：＆＃34;通常被忽略。

如何在允许member和:TEST的{{1}}函数中使用它？

Answer 1

:key参数是一个参数的函数;它应用于序列的每个元素以生成用于测试的值。如果省略，则使用标识函数。

以下是CLHS的一个例子：

(member 2 '((1 . 2) (3 . 4)) :test-not #'= :key #'cdr) =>  ((3 . 4))

Answer 2

在Sequences Library (Section 17)以及17.2.1 Satisfying a Two-Argument Test下的Common Lisp HyperSpec中的17.2.2 Satisfying a One-Argument Test的介绍部分中，:key参数有点隐秘地记录。这是因为它在整个库中的行为是一致的。

很简单，:key指定应用于正在处理的序列或序列的元素的函数。函数的返回值用于代替这些元素。在一些函数语言的术语中，这称为“投影”。元素通过关键功能进行投影。如果你不提供这个参数，你可以想象默认的键函数是identity。

要理解的一件重要事情是，在接受一些对象参数和序列的函数中（例如，搜索序列中出现对象的函数），关键函数不应用于输入对象;只对序列的元素。

第二个重要的事情是:key不能替代该项目，仅用于标识项目的值。例如，搜索序列中的项目的函数将从序列中检索原始项目，即使序列的项目通过:key投影到替代键也是如此。 key函数检索的值仅用于比较。

E.g。如果obj-list是具有可通过名为obj-name的函数访问的名称的对象列表，我们可能会使用"foo"查找名为(find "foo" obj-list :key #'obj-name)的对象。函数obj-name应用于每个元素，并将其结果与字符串"foo"（未应用该函数）进行比较。如果obj-list中存在至少一个该名称的对象，则返回第一个此类对象。

Answer 3

想象一下，我们有一个城市列表：

(defparameter *cities*
   ; City       Population  Area km^2
  '((Paris      2265886     105.4)
    (Mislata    43756       2.06)
    (Macau      643100      30.3)
    (Kallithea  100050      4.75)
    (Nea-Smyrni 73090       3.52)
    (Howrah     1072161     51.74)))

现在我们可以计算人口密度，单位为人/ km ^ 2

(defun city-density (city)
  "the density is the population number divided by the area"
  (/ (second city) (third city)))

现在，我们要计算人口密度低于21000人/公里^ 2的所有城市的列表。

我们从列表中删除了所有较大的文件，并提供了:test-not函数。我们需要提供一个匿名函数来进行测试并计算要比较的城市的密度。

CL-USER 85 > (remove 21000 *cities*
                     :test-not (lambda (a b)
                                 (>= a (city-density b))))

((NEA-SMYRNI 73090 3.52) (HOWRAH 1072161 51.74))

我们可以通过提供数字:test-not函数>=并使用city-density函数作为密钥来计算每个提供的城市的价值，而无需使用匿名函数来简化它。

CL-USER 86 > (remove 21000 *cities* :test-not #'>= :key #'city-density)

((NEA-SMYRNI 73090 3.52) (HOWRAH 1072161 51.74))

因此，既具有测试谓词又具有键函数，可以更轻松地提供用于序列计算的构件...

现在想象我们使用CLOS和城市CLOS对象的列表：

(defclass city ()
  ((name :initarg :name :reader city-name)
   (population :initarg :population :reader city-population)
   (area :initarg :area :reader city-area)))

(defparameter *city-objects*
  (loop for (name population area) in *cities*
        collect (make-instance 'city
                               :name name
                               :population population
                               :area area)))

(defmethod density ((c city))
  (with-slots (population area)
      c
    (/ population area)))

现在我们按上述方法计算列表：

CL-USER 100 > (remove 21000 *city-objects* :test-not #'>= :key #'density)
(#<CITY 42D020DDFB> #<CITY 42D020DF23>)

CL-USER 101 > (mapcar #'city-name *)
(NEA-SMYRNI HOWRAH)

如果我们将密度作为带有吸气剂的缝隙，则可以这样做：

(defclass city ()
  ((name :initarg :name :reader city-name)
   (population :initarg :population :reader city-population)
   (area :initarg :area :reader city-area)
   (density :reader city-density)))

(defmethod initialize-instance :after ((c city) &key)
  (with-slots (density)
      c
    (setf density (density c))))

(defparameter *city-objects*
  (loop for (name population area) in *cities*
        collect (make-instance 'city
                               :name name
                               :population population
                               :area area)))

现在我们按上述方法计算列表，但是 key 是 density 插槽的吸气剂：

CL-USER 102 > (remove 21000 *city-objects* :test-not #'>= :key #'city-density)
(#<CITY 42D026D7EB> #<CITY 42D026D913>)

CL-USER 103 > (mapcar #'city-name *)
(NEA-SMYRNI HOWRAH)

常见的lisp：KEY参数使用

3 个答案: