Question

我在一些证明中使用了几个Inductive定义作为反例。但是，我想通过将它们包含在Section中来封装这些定义。可以使用Definitions隐藏常规Let，但这也适用于Inductive定义吗？ Theorem s怎么样？

让我给出我想要实现的实际内容，因为我可能首先完全采用错误的方式。我想要正式化所有优秀书籍和时间与计算逻辑的证明和练习。 Robert Goldblatt进入Coq。

对于初学者，我们采用经典逻辑，因为这也是本书的作用。

Require Import Classical_Prop.
Require Import Classical_Pred_Type.

接下来，我们以与软件基础相同的方式定义标识符。

Inductive id : Type := Id : nat -> id.

语法的定义。

Inductive modal : Type :=
| Bottom : modal
| V : id -> modal
| Imp : modal -> modal -> modal
| Box : modal -> modal
.

Definition Not (f : modal) : modal := Imp f Bottom.

使用Kripke框架定义语义。

(* Inspired by: www.cs.vu.nl/~tcs/mt/dewind.ps.gz
 *)
Record frame : Type :=
{ Worlds : Type
; WorldsExist : exists w : Worlds, True
; Rel : Worlds -> Worlds -> Prop
}.

Record kripke : Type :=
{ Frame : frame
; Label : (Worlds Frame) -> id -> Prop
}.

Fixpoint satisfies (M : kripke) (x : (Worlds (Frame M))) (f : modal) : Prop
:= match f with
| Bottom => False
| V v => (Label M x v)
| Imp f1 f2 => (satisfies M x f1) -> (satisfies M x f2)
| Box f => forall y : (Worlds (Frame M)), (Rel (Frame M) x y) -> (satisfies M y f)
end.

第一个引理将模态Not与Coq。

相关联

Lemma satisfies_Not
: forall M x f
, satisfies M x (Not f) = ~ satisfies M x f
.
Proof. auto.
Qed.

接下来，我们解除语义以完成模型。

Definition M_satisfies (M : kripke) (f : modal) : Prop
:=  forall w : Worlds (Frame M), satisfies M w f.

我们展示了它对Not连词的含义。

Lemma M_satisfies_Not : forall M f
,   M_satisfies M (Not f) -> ~ M_satisfies M f
.
Proof. 
  unfold M_satisfies.
  intros M f Hn Hcontra.
  destruct (WorldsExist (Frame M)).
  specialize (Hn x); clear H.
  rewrite satisfies_Not in Hn.
  specialize (Hcontra x). auto.
Qed.

事情就是这样。上述引理的反面并不成立，我想通过一个反例展示这一点，展示一个它不能保持的模型。

Inductive Wcounter : Set := | x1:Wcounter | x2:Wcounter | x3:Wcounter.

Lemma Wcounter_not_empty : exists w : Wcounter, True.
Proof. exists x1. constructor. Qed.

Inductive Rcounter (x : Wcounter) (y : Wcounter) : Prop :=
| E1 : x = x1 -> y = x2 -> Rcounter x y
| E2 : x = x2 -> y = x3 -> Rcounter x y
.

Definition Lcounter : Wcounter -> id -> Prop
:= fun x i => match x with
| x1 => match i with | Id 0 => True | _ => False end
| x2 => match i with | Id 1 => True | _ => False end
| x3 => match i with | Id 0 => True | _ => False end
end.

Definition Fcounter : frame := Build_frame Wcounter Wcounter_not_empty Rcounter.

Definition Kcounter : kripke := Build_kripke Fcounter Lcounter.

接下来Ltac让我无法输入详细信息assert。

Ltac counter_example H Hc := match type of H with
| ?P -> ~ ?Q => assert(Hc: Q)
| ?P -> (?Q -> False) => assert(Hc: Q)
| ?P -> ?Q => assert(Hc: ~Q)
end.

最后，我使用此反例来证明以下Lemma。

Lemma M_not_satisfies_Not : ~ forall M f
,   (~ M_satisfies M f) -> M_satisfies M (Not f)
.
Proof.
  apply ex_not_not_all. exists Kcounter.
  apply ex_not_not_all. exists (V (Id 0)).
  unfold M_satisfies. simpl.
  intro Hcontra. unfold not in Hcontra.
  counter_example Hcontra Hn2.
    apply ex_not_not_all. exists x1. simpl. auto.
  apply Hn2. apply Hcontra. apply ex_not_not_all; exists x2. simpl. auto.
Qed.

我最好使用remember策略来定义证明中的反例，但我认为它不能用于Inductive定义。所有与反例相关的定义都作为我理论的一部分输出，我不愿意这样做。它仅用于M_not_satisfies_Not的证明。实际上我甚至不想导出这个Lemma，因为它不是很有用。我只是说它M_satisfies_Not不能等同。

Answer 1

Module不会隐藏定义，而是使用Module CounterExample. Import Definitions. Inductive Wcounter : Set := x1 | x2 | x3. ... Lemma M_not_satisfies_Not : ... End CounterExample.。例如，将计数器示例放在模块中。

CounterExample

在此阶段，仅在顶级定义.v。

如果您不想要那么，那么您可以将定义放在一个.v文件中，将计数器示例放在导入定义的另一个文件中。实际上，它的工作方式是将decompress文件转换为单独的模块。

本地归纳定义和定理

1 个答案: