Question

我有以下代码：

(defn -db-producer-factory [order-ids-chan next-chan]
  (thread
    (prn "db starting...")
    (while true
      (do
        (prn "db starting2...")
        ;;
        ;; issue spot!
        ;; it stays blocked here-- the orderid doesnt come off the chan
        ;;
        (let [order-id (<!! order-ids-chan)]
          (prn "db->" order-id)
          (condp = order-id
            :finished (>!! next-chan :finished)
            :>> (supress-w-nextexc
                  (->>
                    ; get denorm'd order
                    (-> (r/-get-order :live order-id)
                        denorm/order->denormalized)
                    ; put in a map to avoid nils
                    (hash-map :data)
                    (>!! next-chan)))))))))

(defn -stats-producer-factory [stats-db-chan next-chan]
  (thread
    (while true
      (do
        (let [msg (<!! stats-db-chan)
              data (:data msg)]
          (when data
            (do
              (prn "stats-> " (-> data :order :order-id))
              (supress-w-nextexc
                (q/stats-order-insert (-> data :order)))
              (supress-w-nextexc
                (q/stats-item-insert (-> data :items)))))
          (>!! next-chan msg))))))

(defn -do-orderids [orderids]
  (let [finished-chan (chan)
        order-ids-chan (chan)
        stats-db-chan (chan)
        db-producer (-db-producer-factory order-ids-chan stats-db-chan)
        stats-producer (-stats-producer-factory stats-db-chan finished-chan)]

    (prn "pre-pub")
    ;; pub ids and finished message
    (map #(>!! order-ids-chan %) (conj orderids :finished))
    ;; wait for finish
    (prn "finished? " (<!! finished-chan))
    ;; allow time for finishing
    ;(Thread/sleep 3000)
    ;; close all chans
    (map close! [finished-chan order-ids-chan stats-db-chan db-producer stats-producer])
    ))

此过程是通过致电-do-orderids (-do-orderids [123])来启动的。

执行的输出是：

"db starting..."
"pre-pub"
"db starting2..."

然后它阻止了。为什么不在“问题点”传递orderid？

Answer 1

您的程序会阻止，因为db-producer被阻止等待订单ID，但实际上从未在order-ids-chan上收到订单ID。

那是因为map是懒惰的。所以，在这个调用中

(map #(>!! order-ids-chan %) (conj orderids :finished))

永远不会调用映射函数，也不会将任何订单ID放在频道上。

Clojure经验法则：

永远不要将map用于副作用！请改用run!。

我认为用run!替换该行中的map（以及在频道上调用close!的最后一行）应该修复它。

不相关：您使用的所有do表单都是多余的，您可以安全地删除它们并降低嵌套级别。

clojure core.async线程块

1 个答案: