如何将可点击链接添加到自定义Inno Setup WelcomeLabel？

Question

我有一个带有自定义WelcomeLabel2消息的Inno安装程序。

[Messages]
WelcomeLabel2=Lorem ipsum dolor sit amet CLICK_HERE consectetur adipiscing elit.

我正在努力使CLICK_HERE成为网站的可点击链接。

我想知道的另一件事是如何使这个CLICK_HERE文本粗体。

我怎样才能实现这个目标？

韩国社交协会！

Answer 1

这并不容易。

要创建可整体点击的标签，您可以使用以下代码：

procedure OpenBrowser(Url: string);
var
  ErrorCode: Integer;
begin
  ShellExec('open', Url, '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
end;

procedure LinkClick(Sender: TObject);
begin
  OpenBrowser('https://www.example.com/');
end;

procedure InitializeWizard;
var
  Link: TLabel;
begin
  Link := TLabel.Create(WizardForm);
  Link.Left := ???;
  Link.Top := ???;
  Link.Parent := WizardForm.WelcomePage;
  Link.Caption := 'CLICK_HERE';
  Link.OnClick := @LinkClick;
  Link.ParentFont := True;
  Link.Font.Style := Link.Font.Style + [fsUnderline, fsBold];
  Link.Font.Color := clBlue;
  Link.Cursor := crHand;
end;

另见Show License Agreement link in Inno Setup while installation。

虽然创建一个只有部分文本可点击的标签是一种更难的方式。如果文本适合一行，则可以通过将三个标签彼此相邻堆叠来实现（首先是前导静态文本，然后是链接，然后是尾随静态文本）。但是如果文本不适合一行，那就不可行，因为标签会相互重叠。

或者，您可以使用链接创建RTF文档，并使用只读TRichEditViewer显示它：

procedure InitializeWizard;
var
  RichViewer: TRichEditViewer;
begin
  RichViewer := TRichEditViewer.Create(WizardForm);
  RichViewer.Left := WizardForm.WelcomeLabel2.Left;
  RichViewer.Top := WizardForm.WelcomeLabel2.Top;
  RichViewer.Width := WizardForm.WelcomeLabel2.Width;
  RichViewer.Height := WizardForm.WelcomeLabel2.Height;
  RichViewer.Parent := WizardForm.WelcomeLabel2.Parent;
  RichViewer.BorderStyle := bsNone;
  RichViewer.TabStop := False;
  RichViewer.ReadOnly := True;
  WizardForm.WelcomeLabel2.Visible := False;

  RichViewer.RTFText :=
    '{\rtf1 Lorem ipsum dolor sit amet ' +
    '{\b {\field{\*\fldinst{HYPERLINK "https://www.example.com/" }}' + 
    '{\fldrslt{CLICK_HERE}}}} ' +
    'consectetur adipiscing elit.}';
end;

要更改链接颜色，请参阅Inno Setup - How to change the color of the hyperlink in RTF text?