我正在尝试使用Delphi从Windows注册表获取BIOS版本。我的问题是所有Windows版本的子项路径都不相同。
Windows 10:Reg.OpenKey('\HARDWARE\DESCRIPTION\SYSTEM\BIOS',False)
Windows 7:Reg.OpenKey('\HARDWARE\DESCRIPTION\SYSTEM',False)
有没有办法找到BIOS版本,无论它实际上是什么路径?
答案 0 :(得分:1)
从Windows Vista开始,您可以使用Win32_BIOS
WMI类来获取BIOS版本。试试这个示例代码。
{$APPTYPE CONSOLE}
{$R *.res}
uses
System.SysUtils,
Winapi.ActiveX,
System.Win.ComObj,
System.Variants;
procedure GetWin32_BIOSInfo;
const
WbemUser ='';
WbemPassword ='';
WbemComputer ='localhost';
wbemFlagForwardOnly = $00000020;
var
FSWbemLocator : OLEVariant;
FWMIService : OLEVariant;
FWbemObjectSet: OLEVariant;
FWbemObject : OLEVariant;
oEnum : IEnumvariant;
iValue : LongWord;
begin;
FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
FWMIService := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
FWbemObjectSet:= FWMIService.ExecQuery('SELECT * FROM Win32_BIOS','WQL',wbemFlagForwardOnly);
oEnum := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
while oEnum.Next(1, FWbemObject, iValue) = 0 do
begin
Writeln(Format('SerialNumber %s',[String(FWbemObject.SerialNumber)]));
Writeln(Format('SMBIOSBIOSVersion %s',[String(FWbemObject.SMBIOSBIOSVersion)]));
Writeln(Format('Version %s',[String(FWbemObject.Version)]));
Writeln('');
FWbemObject:=Unassigned;
end;
end;
begin
try
CoInitialize(nil);
try
GetWin32_BIOSInfo;
finally
CoUninitialize;
end;
except
on E:EOleException do
Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
on E:Exception do
Writeln(E.Classname, ':', E.Message);
end;
Writeln('Press Enter to exit');
Readln;
end.