Question

我正在尝试使用Yampa-Framework模拟一个弹跳球：给定一个初始的x位置，高度和速度，球应该根据重力规则反弹。信号功能以“提示 - 事件”为输入，这个想法是“当球被倾斜时，它的速度应该加倍”。

球反弹很好，但每次发生倾翻事件时，该功能都会进入无限循环。我想我可能需要添加延迟（dSwitch，pre，notYet？），但我不知道如何。任何帮助将不胜感激！

{-# LANGUAGE Arrows #-} 

module Ball where

import FRP.Yampa

type Position  = Double
type Velocity  = Double
type Height    = Double

data Ball = Ball {
      height :: Height,
      width  :: Position,
      vel    :: Velocity
} deriving (Show)

type Tip = Event ()

fly :: Position -> (Height, Velocity) -> SF Tip (Ball, Event (Height,Velocity))
fly w0 (h0, v0) = proc tipEvent -> do
     let tip = (tipEvent == Event ())
     v <- (v0+) ^<< integral -< -10.0
     h <- (h0+) ^<< integral -< v 
     returnA -< (Ball h w0 v, 
                 if h < 0 then Event (0,(-v*0.6)) 
                  else if tip then Event (h, (v*2))
                   else NoEvent)

bounce w (h,v) = switch (fly w (h,v)) (bounce w)   

runBounce w (h,v)  = embed (bounce 10 (100.0, 10.0)) (deltaEncode 0.1 [NoEvent, NoEvent, NoEvent, Event (), NoEvent])

编辑：当一个小费发生时，我设法通过反馈旗帜来避免无限循环，但这仍然不是正确的做法...

fly :: Position -> (Height, Velocity, Bool) -> SF Tip (Ball, Event (Height,Velocity,Bool))
fly w0 (h0, v0, alreadyTipped) = proc tipEvent -> do
     let tip = tipEvent == Event () && (not alreadyTipped)
     v <- (v0+) ^<< integral -< -10.0
     h <- (h0+) ^<< integral -< v 
     returnA -< (Ball h w0 v, 
                 if h < 0 then Event (0,(-v*0.6), False) 
                  else if tip then Event (h, (v*2), True)
                   else NoEvent)

bounce w (h,v,alreadyTipped) = switch (fly w (h,v,alreadyTipped)) (bounce w)

Answer 1

经过几天黑客攻击后，我想我找到了答案。诀窍是使用notYet将切换事件延迟到下一个时间点，以便在“旧”倾翻事件消失时发生切换（以及因此对fly的递归调用）。 second函数确保只有结果元组(Ball, Event (..))的第二部分才能通过notYet。这消除了无限循环，但也改变了语义：切换现在发生一个“时间步”，这反过来导致不同的速度。

这个Yampa实际上相当不错，遗憾的是没有太多文档要找。我仍然无法找出pre和iPre函数的优点，我认为它们可以在类似的上下文中使用。

fly :: Position -> (Height, Velocity) -> SF Tip (Ball, Event (Height,Velocity))
fly w0 (h0, v0) = proc tipEvent -> do
     let tip = tipEvent == Event ()
     v <- (v0+) ^<< integral -< -10.0
     h <- (h0+) ^<< integral -< v 
     returnA -< (Ball h w0 v, 
                 if h < 0 then Event (0,-v*0.6) 
                  else if tip then Event (h, v*2)
                   else NoEvent)

bounce w (h,v) = switch (fly w (h,v) >>> second notYet) (bounce w)

为什么这个Yampa球弹跳进入无限循环？

1 个答案: