Question

我有一个Windows 10命令提示符正在运行并等待输入，我希望使用第二个命令提示符自动执行连续和实时输入。我已经获得了第二个命令提示符来提取所需的变量，我希望将它发送到正在等待输入的其他命令提示符。

“等待输入”命令提示符必须实时运行，因为它连接到连接到微控制器的Plink（不是SSH会话，因此不使用-m命令）。所以用函数调用无法实现（至少我不认为）。

我看到它可以在UNIX环境中完成：https://askubuntu.com/questions/496914/write-command-in-one-terminal-see-result-on-other-one

提前致谢，请指教，

- 一个充满希望的初学者

Answer 1

批处理代码启动2个管道进程，一个用于获取键盘输入和写入文件，另一个用于读取写入的数据。请注意，每个进程都没有cmd窗口，但有两个新进程在运行。如果您需要两个控制台，可以使用cmd /c或start。

有帮助吗？

@echo off

set "pipefile=pipefile.txt"

if "%~1" neq "" goto %1

copy nul "%pipefile%" >nul
"%~F0" getInput >>"%pipefile%" | "%~F0" readInput <"%pipefile%"
echo(
echo(Batch end...
ping localhost -n 1 >nul
del /F /Q "%pipefile%" 2>nul
exit/B



:getInput
set "input="
set/P "input="<CON
echo(%input%
if /I "%input%" equ "EXIT" exit
goto:getInput


:readInput
setlocal enableDelayedExpansion
set/P="enter some data [EXIT to exit] "
for /l %%. in () do (
  set "input="
  set/P "input="
  if defined input (
    if /I "!input!" equ "EXIT" exit
    set/P="enter some data [EXIT to exit] "
  )
   ping 1.1.1.1 -w 10 -n 1 >nul 2>nul & rem avoid processor load (may be removed) 
)

运行两个控制台窗口

@echo off

set "pipefile=pipefile.txt"

if "%~1" neq "" goto %1

del /F /Q "%pipefile%" 2>nul
copy nul "%pipefile%" >nul

start "writer" cmd /c ^""%~f0" readInput ^<"%pipefile%" ^"
start "reader" cmd /c ^""%~f0" getInput ^"

echo(
Echo batch end...
ping localhost -n 1 >nul
goto :EOF


:getInput
set "input="
set/P "input=enter some data [EXIT to exit] "
echo(%input%>>"%pipefile%"
if /I "%input%" equ "EXIT" exit
goto:getInput

:readInput
setlocal enableDelayedExpansion
for /l %%. in () do (
  set "input="
  set /p "input="
  if defined input (
    if /I "!input!" equ "EXIT" exit
    echo(!input!
  )
   ping 1.1.1.1 -w 10 -n 1 >nul 2>nul & rem avoid processor load (may be removed) 
)

在本机窗口中运行两个命令提示符终端，如何将一个输出重定向到另一个的输入？

1 个答案: