Vala：如何在不解压缩的情况下检索zip存档中所有文件的名称？

Question

在erlang中是否有像zip:list_dir这样的vala中的任何函数？我找到了libgsf，但我不想解压缩zip文件。

Answer 1

您可以使用libarchive。

void check_ok (Archive.Result r) throws IOError {
    if (r == Archive.Result.OK)
        return;
    if (r == Archive.Result.WARN)
        return;
    throw new IOError.FAILED ("libarchive returned an error");
}

int main () {

    try {
        var a = new Archive.Read ();
        check_ok (a.support_filter_all ());
        check_ok (a.support_format_all ());
        check_ok (a.open_filename ("archive.zip", 10240));

        unowned Archive.Entry entry;
        while (a.next_header (out entry) == Archive.Result.OK) {
            stdout.printf ("%s\n", entry.pathname ());
            a.read_data_skip ();
        }
    }
    catch (IOError e) {
        stderr.printf (e.message + "\n");
        return 1;
    }

    return 0;
}

使用valac ListZip.vala --pkg libarchive --pkg gio-2.0进行编译。

IOError errordomain只需要GIO。实际上，您需要使用一些操作失败的描述性消息来扩展check_ok方法。

您还可以将libarchive限制为仅允许zip文件。我翻译了example from the upstream wiki。