定义多个顶级表单的球拍宏？

Question

我发现自己定义了除了名称之外的相同定义的语法参数，所以我决定编写一个宏来使这更简单：

(define-syntax (test-case-parameter stx)
  (syntax-parse stx
    [(_ parameter:id)
     #'(define-syntax-parameter parameter
         (lambda (stx)
           (raise-syntax-error stx "Can only be used inside test-case.")))]))

(test-case-parameter a)
(test-case-parameter b)
(test-case-parameter c)

然而，我不想重复宏名称，而是希望能够写出：

(test-case-parameter a b c)

但是我不知道如何使用普通的省略号语法来做这件事，因为我需要将所有内容都包装在begin中，这会创建一个新的范围，我想要所有的语法参数好像我已经把它们写成了每个顶级的。什么是实现这个目标的正确方法？

Answer 1

答案是使用begin。 begin很奇怪，因为它在顶层的行为与在表达式上下文中的行为不同。在顶层，它具有您希望此宏所需的拼接行为，但在表达式上下文中具有您所指的范围行为。

所以你可以这样定义你的宏：

#lang racket
(require racket/stxparam (for-syntax syntax/parse))

(define-syntax (define-test-case-parameters stx)
  (syntax-parse stx
    [(_ parameter:id ...)
     #'(begin
         (define-syntax-parameter parameter
           (lambda (stx)
             (raise-syntax-error stx "Can only be used inside test-case.")))
         ...)]))

(define-test-case-parameters a b c)

您可以在DrRacket的宏步进器中看到begin顶级拼接的工作原理：

Answer 2

创建一个接受多个标识符的新宏，并将其扩展为使用单个标识符的版本的一系列用法。

#lang racket
(require (for-syntax syntax/parse)
         racket/stxparam)

(define-syntax (test-case-parameter-helper stx)
  (syntax-parse stx
    [(_test-case-parameter-helper parameter:id)
     (syntax/loc stx
       (define-syntax-parameter parameter
         (lambda (stx)
           (raise-syntax-error stx "Can only be used inside test-case."))))]))

(define-syntax (test-case-parameter stx)
  (syntax-parse stx
    [(_test-case-parameter parameter:id ...)
     (syntax/loc stx
       (begin
         (test-case-parameter-helper parameter)
         ...))]))

(test-case-parameter a b c)