Question

我已经为可配置变量开发了一个模型，这意味着变量可以由参数定义，通过实际输入指定，或者保留未定义，以便可以解决。

model ConfigurableReal   

"Configurable variable that can be set by parameter, by real input, or left undetermined"

  parameter Boolean isSpecifiedByParameter = false 
    "true if value is specified by paramter"
    annotation(Dialog(group="Specify by Parameter", enable = not isSpecifiedByInput));

  parameter Boolean isSpecifiedByInput = false 
    "true if value is specified by real input"
    annotation(Dialog(group = "Specify by Real Input", enable=not isSpecifiedByParameter));

  parameter Real specifiedValue(unit=unitString) = 0 
    "specified value to use if isSpecifiedByParameter == true"
    annotation(Dialog(group="Specify by Parameter", enable = isSpecifiedByParameter));

  // Conditionally declare the realInput
  Modelica.Blocks.Interfaces.RealInput realInput if isSpecifiedByInput
    annotation (Placement(transformation(extent={{-140,-20},{-100,20}})));

  Real value "active value";

protected 
  Modelica.Blocks.Sources.Constant constantBlock(final k = specifiedValue) if isSpecifiedByParameter 
    "constant block to hold specified input";

  Modelica.Blocks.Interfaces.RealInput value_ "connected value";

equation 
  value = value_;

  // Connect the real input to the value if the real input exists
  // This only happens if isSpecifiedByInput==true, because the RealInput is
  // conditionally declared above
  connect(realInput, value_);

  // Connect the constant block to the value if the value is specified by parameter
  // This only happens if isSpecifiedByParameter == true, because the Constant is
  // conditionally declared above  
  connect(constantBlock.y, value_);

   annotation (Icon(coordinateSystem(preserveAspectRatio=false), graphics={
        Rectangle(
          extent={{-80,40},{80,-40}},
          lineColor={28,108,200},
          fillColor={255,255,255},
          fillPattern=FillPattern.Solid),
        Text(
          extent={{-70,30},{70,-32}},
          lineColor={28,108,200},
          textString="Config
Variable"),
        Text(
          extent={{-100,80},{100,50}},
          lineColor={28,108,200},
          fillColor={255,255,255},
          fillPattern=FillPattern.Solid,
          textString=DynamicSelect("", "value = " + String(value, significantDigits=4))),
        Text(
          extent={{-100,-50},{100,-80}},
          lineColor={28,108,200},
          fillColor={255,255,255},
          fillPattern=FillPattern.Solid,
          textString="%name")}),
        Diagram(
        coordinateSystem(preserveAspectRatio=false)));
end ConfigurableReal;

现在我想以一种利用数量/单位类型而不是仅利用Reals的方式扩展模型。是否可以通过参数分配变量类型？例如，是否可以声明一个变量，如下所示？

parameter String variableType = "Pressure";
parameter typeOf(variableType) variableType;

如果是这样，我可以在ConfigurableReal模型中定义变量类型以引用variableType对象并通过以下方式编写可配置的压力模型：

model ConfigurablePressure extends ConfigurableReal(final variableType="Pressure");

如果没有，Modelica中是否存在类似C＃Type Parameters的内容？

最后，我真的想找到一种扩展我的ConfigurableReal模型的方法，使它可以是ConfigurablePressure，ConfigurableTemperature，ConfigurableMassFlowRate，...，包含参数输入和模拟结果中的单位，而无需复制和粘贴每个变量类型的模型代码，并在每个类中手动分配变量类型。

非常感谢任何帮助。

谢谢，贾斯汀

Answer 1

贾斯汀，你真正想要的是使用redeclare + replaceable。你提到C＃类型参数。 Modelica确实有类似的东西，但由于Modelica的数学约束，它们看起来并不完全（语法上）并且它们有一些额外的约束。

如果您还没有在我的书中阅读the chapter on Architecture，那么这将为您提供一个开始。

要完成与C＃类型参数的类比，请考虑以下模型：

model Circuit
  replaceable Resistor R constrainedby Element;
  ...
end Circuit;

这表示R必须是Element的子类型。默认情况下，它是Resistor，但您可以更改它。请注意Element和Resistor或两种类型。因此，您要更改R的类型。您可以使用redeclare进行更改（参见手册）。

在这种情况下，“类型参数”仅适用于一个变量R。但是您可以使用更多C＃方式执行此操作：

model Circuit
  replaceable model X = Resistor constrainedby Element;
  X R1;
  X R2;
}

在C＃中，这将是：

class Circuit<X> where X : Element {
  X R1;
  X R2;
}

（除了我记得C＃没有默认值）

我必须跑步，但我希望有所帮助。

是否可以通过Modelica中的参数设置变量类型？

1 个答案: