Question

我有一个查询，我计算多年的分组。有些年份没有可计算的项目，因此没有结果。我想让SPARQL在这些年里返回零。

我正在使用维基数据查询服务https://query.wikidata.org，而我目前的解决方案是制作一系列值并与实际查询结合使用。它对我来说看起来有点笨拙。还有更好的方法吗？

#defaultView:BarChart
select ?year ?number_of_pages ?work_label where {
  {
    select ?year (sample(?pages) as ?number_of_pages) ?work_label       
    where {
      {
        select * where {
          values (?year ?pages ?work_label) {
            ("2000" "0"^^xsd:integer "_") 
            ("2001" "0"^^xsd:integer "_") 
            ("2002" "0"^^xsd:integer "_") 
            ("2003" "0"^^xsd:integer "_") 
            ("2004" "0"^^xsd:integer "_") 
            ("2005" "0"^^xsd:integer "_") 
            ("2006" "0"^^xsd:integer "_") 
            ("2007" "0"^^xsd:integer "_") 
            ("2008" "0"^^xsd:integer "_") 
            ("2009" "0"^^xsd:integer "_") 
            ("2010" "0"^^xsd:integer "_") 
            ("2011" "0"^^xsd:integer "_")
            ("2012" "0"^^xsd:integer "_")
            ("2013" "0"^^xsd:integer "_")
            ("2014" "0"^^xsd:integer "_")
            ("2015" "0"^^xsd:integer "_")
            ("2016" "0"^^xsd:integer "_")
          }
        }
      }
      union {
        ?work wdt:P50 wd:Q18921408 .
        ?work wdt:P1104 ?pages .
        ?work wdt:P577 ?date . 
        ?work rdfs:label ?long_work_label . filter(lang(?long_work_label) = 'en')
        bind(substr(?long_work_label, 1, 20) as ?work_label)
        bind(str(year(?date)) as ?year) 
      }
    } 
    group by ?year ?work ?work_label
    order by ?year 
  }
}

Answer 1

您不需要这么多嵌套查询。这是一个简单的解决方案：

#defaultView:BarChart
select ?year ?pages ?label       
where {
  # iterating over years
  values ?year {
    "2000" "2001" "2002" "2003" "2004" "2005" 
    "2006" "2007" "2008" "2009" "2010" "2011" 
    "2012" "2013" "2014" "2015" "2016" 
  }

  # binding defaults
  bind( 0  as ?default_pages)
  bind("_" as ?default_label)

  # if there is a work in the given year, ?work_pages and ?work_label will be bound
  optional {
    ?work wdt:P50 wd:Q18921408;
          wdt:P1104 ?work_pages;
          wdt:P577  ?work_date. 
    bind(str(year(?work_date)) as ?year).

    ?work rdfs:label ?long_work_label. 
    filter(lang(?long_work_label) = 'en').
    bind(substr(?long_work_label, 1, 20) as ?work_label)
  }

  # either take ?work_pages/label value or default and bind it as the result ?pages/label
  bind(coalesce(?work_pages, ?default_pages) as ?pages)
  bind(coalesce(?work_label, ?default_label) as ?label)
} 
order by ?year

以下是结果截图：

此处的关键是optional + bind / coalesce的组合。一般模式是

bind(... as ?default_foo)

optional { 
  # try to get value ?foo
}

bind(coalesce(?foo, ?default_foo) as ?result_foo)

coalesce返回它可以的第一个值（绑定/计算没有错误）。因此，如果您尝试在optional { ... }中获取的值未绑定，则将采用默认值并将其绑定为结果。写一个更冗长的方式：

bind(if(bound(?foo), ?foo, ?default_foo) as ?result_foo)

但coalesce更好，因为您可以在其中传递多个值。在更复杂的查询中，它可能很有用：请参阅this example。

如何在计数时获取SPARQL查询的默认返回值

1 个答案: