Question

如何在存储过程中使用tsql循环逗号分隔变量

因此，例如我的列表看起来像这样

"1,2,3,4,5,6,7,8,9,10"

我会循环思考这个列表并制作一些必要的表格基于此列表插入

Answer 1

你可以做几个方法，但如果这是一个ID的列表，它也可以这样做。它会改变你的列表格式。

UPDATE table
SET column = value
WHERE ID in ('1','2','3','4','5','6','7','8','9','10')

你也可以做一个循环

DECLARE @List CHAR(100)
DECLARE @ListItem int
DECLARE @Pos int
SET @List = '1,2,3,4,5,6,7,8,9,10'
WHILE LEN(@List) > 0
BEGIN
    --Pull Item Frim List
    SET @Pos = CHARINDEX(',', @List)
    IF @Pos = 0
        BEGIN
            SET @ListItem = @List
        END
    ELSE
        BEGIN
            SET @ListItem = SUBSTRING(@List, 1, @Pos - 1)
        END

    UPDATE table
    SET column = value
    WHERE ID = @ListItem

    --Remove Item Frim List
    IF @Pos = 0
        BEGIN
               SET @List = ''
        END
    ELSE
        BEGIN
                SET @List = SUBSTRING(@List, @Pos + 1, LEN(@List) - @Pos)
        END
END

Answer 2

我会尝试避免循环并直接从逗号列表中插入行。

使用表值参数（SQl Server 2008中的新增功能）。通过创建实际的表参数类型来设置它：

CREATE TYPE IntTableType AS TABLE (ID INTEGER PRIMARY KEY)

您的程序将是：

Create Procedure up_TEST
    @Ids IntTableType READONLY
AS

SELECT * 
    FROM ATable a
    WHERE a.Id IN (SELECT ID FROM @Ids)

RETURN 0
GO

如果您不能使用表值参数，请参阅："Arrays and Lists in SQL Server 2005 and Beyond, When Table Value Parameters Do Not Cut it" by Erland Sommarskog，那么有很多方法可以在SQL Server中拆分字符串。本文涵盖几乎所有方法的PRO和CON。通常，您需要创建拆分功能。这就是如何使用split函数插入行：

INSERT INTO YourTableA (colA)
    SELECT
        b.col1
        FROM dbo.yourSplitFunction(@Parameter) b

I prefer the number table approach to split a string in TSQL但是有很多方法可以在SQL Server中拆分字符串，请参阅上一个链接，该链接解释了每个链接的PRO和CON。

要使Numbers Table方法起作用，您需要进行一次性表设置，这将创建一个包含1到10,000行的表Numbers：

SELECT TOP 10000 IDENTITY(int,1,1) AS Number
    INTO Numbers
    FROM sys.objects s1
    CROSS JOIN sys.objects s2
ALTER TABLE Numbers ADD CONSTRAINT PK_Numbers PRIMARY KEY CLUSTERED (Number)

设置Numbers表后，创建此拆分功能：

CREATE FUNCTION [dbo].[FN_ListToTable]
(
     @SplitOn  char(1)      --REQUIRED, the character to split the @List string on
    ,@List     varchar(8000)--REQUIRED, the list to split apart
)
RETURNS TABLE
AS
RETURN 
(

    ----------------
    --SINGLE QUERY-- --this will not return empty rows
    ----------------
    SELECT
        ListValue
        FROM (SELECT
                  LTRIM(RTRIM(SUBSTRING(List2, number+1, CHARINDEX(@SplitOn, List2, number+1)-number - 1))) AS ListValue
                  FROM (
                           SELECT @SplitOn + @List + @SplitOn AS List2
                       ) AS dt
                      INNER JOIN Numbers n ON n.Number < LEN(dt.List2)
                  WHERE SUBSTRING(List2, number, 1) = @SplitOn
             ) dt2
        WHERE ListValue IS NOT NULL AND ListValue!=''

);
GO

您现在可以轻松地将CSV字符串拆分为表格并加入其中：

Create Procedure up_TEST
@Ids VARCHAR(MAX)
AS
SELECT * FROM ATable a
WHERE a.Id IN (SELECT ListValue FROM dbo.FN_ListToTable(',',@Ids))
GO

或从中插入行：

Create Procedure up_TEST
@Ids VARCHAR(MAX)
,@OtherValue varchar(5)
AS
INSERT INTO YourTableA
        (colA, colB, colC)
    SELECT
        ListValue, @OtherValue, GETDATE()
        FROM dbo.FN_ListToTable(',',@Ids)
GO

Answer 3

使用CTE（公用表表达式）是最优雅的解决方案我认为在stackoverflow上检查这个问题，

T-SQL: Opposite to string concatenation - how to split string into multiple records

存储过程中的T-SQL循环

3 个答案: