Question

我正在编写一个聊天客户端/服务器，并且具有以下带有套接字的代码，并返回一个clojure.core.async / channel，可以更轻松地写入套接字。

我的问题是，尽管是类型提示，我仍然会得到反映警告，无法解析对.write的调用。

(ns chat.main
  (:require [clojure.core.async :as a :refer [>! >!! <! <!! go thread chan]])

  (:import [java.net Socket ServerSocket]
           [java.io InputStream BufferedReader InputStreamReader OutputStream BufferedOutputStream PrintWriter]))

(set! *warn-on-reflection* true)

(defn new-output-chan [^Socket sock]
  (let [^OutputStream out (.getOutputStream sock)
        ^PrintWriter p-out (PrintWriter. out)
        out-chan (chan)]
    (go
      (while (.isConnected sock)
        (let [^String message (<! out-chan)]
          (.write p-out message) ; <---------- Here
          (.flush p-out)))
      (a/close! out-chan))
    out-chan))

给出：

Reflection warning, C:\Users\slomi\IdeaProjects\chat\src\chat\main.clj:44:5 - call to method write on java.io.PrintWriter can't be resolved (argument types: unknown).

我不知道如何让它更清楚。明确暗示了p-out和message。奇怪的是，对flush的调用很好。

我该如何解决这个问题？

Answer 1

问题是go实际上将您的代码重写为状态机（您可以使用macroexpand-1检查转换，但结果非常冗长，所以我没有在此处包含它）。不幸的是，看起来这种转换不会保留类型提示。

也许有一个更好的解决方案，但是如果你将调用拉出到自己的函数中，你可以输入提示，因为它不会被go重写：

(defn new-output-chan [^Socket sock]
  (let [^OutputStream out (.getOutputStream sock)
        ^PrintWriter p-out (PrintWriter. out)
        out-chan (chan)
        write #(.write p-out ^String %)]
    (go
      (while (.isConnected sock)
        (let [message (<! out-chan)]
          (write message)
          (.flush p-out)))
      (a/close! out-chan))
    out-chan))

Clojure给出反射警告depsite类型提示

1 个答案: