Question

我是XSLT的新手，正在尝试转换xml：

`<xml>
    <id1>1</id1>
    <id2>2</id2>
    <abc>
        <a>a</a>
        <b>b</b>
        <c>c</c>
    </abc>
</xml>`

到另一个xml：

`<xml>
    <id1>1</id1>
    <abc>
        <a>a</a>
        <b>b</b>
    </abc>
 </xml>`

我可以使用哪种样式表来实现这一目标？

转型规则： id1，abc / a和abc / b元素将被保留。所有其他元素都要被忽略，也就是说，我有一组特定的元素，我希望保留，而忽略所有其他元素。

Answer 1

如果要保留“白色”节点列表，那么实现它的最简单方法是使用它来有选择地应用模板：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/xml">
    <xsl:copy>
        <xsl:apply-templates select="id1 | abc"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="abc">
    <xsl:copy>
        <xsl:apply-templates select="a | b"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

或者，如果您愿意：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/xml">
    <xsl:copy>
        <xsl:copy-of select="id1"/>
        <xsl:apply-templates select="abc"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="abc">
    <xsl:copy>
        <xsl:copy-of select="a | b"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

XSLT样式表选择特定的子元素

1 个答案: