Question

我正在尝试为简单的编程语言（家庭作业）构建AST。但是我不能让它起作用：似乎中间值（$ 1，$ 2，...）无效，并且与我在“子表达式”中返回的内容不对应。

这是我项目的Bison代码（我认为问题出在这里而不是我的AST函数中）：我把注释放在遇到无效值的地方。这是我使用Bison的第一个项目，所以我不确定我是否正确地做事。

我也使用Flex，但flex代码似乎正常工作。

感谢。

%{
#include <stdio.h>

#include "node.h"
#include "print_node.h"

int yylex();
int yyerror(char * s);

CommandNode * root = NULL;
%}

%union
{
    struct ExpressionNode * expression;
    struct CommandNode    * command;
    int    number;
    char * var;
}

%type   <expression>    E T F
%type   <command>       C

%token  <number>        NUMBER
%token  <var>           VAR

%token                  AF SKIP SEQ IF THEN ELSE WHILE DO ADD SUB MUL EOL

%%

root:           C EOL      { root = $1; return 0; /************ $1 seems to be garbage ************/ }
                ;

E:              E ADD T    { $$ = newAddNode($1,$3); }
        |       E SUB T    { $$ = newSubNode($1,$3); }
        |       T          { $$ = $1;                }
        ;

T:              T MUL F    { $$ = newMulNode($1,$3); }
        |       F          { $$ = $1;                }
        ;

F:              '(' E ')'  { $$ = $2;                }
        |       NUMBER     { $$ = newNumberNode($1); }
        |       VAR        { $$ = newVarNode($1);    }
        ;

C:              SKIP                 { $$ = newSkipNode();       }
        |       VAR AF E             { $$ = newAfNode($1,$3);    }
        |       '(' C ')'            { $$ = $2;                  }
        |       IF E THEN C ELSE C   { $$ = newIfNode($2,$4,$6); }
        |       WHILE E DO C         { $$ = newWhileNode($2,$4); }
        |       C SEQ C              { $$ = newSeqNode($1,$3); /************ $1 and $3 seems to be garbage ************/ }
        ;

%%

int main()
{
    yyparse();
}

int yyerror(char * s)
{
    fprintf(stderr, "yyerror: %s\n", s);
}

Answer 1

最常见的是，您描述的症状发生是因为您的词法分析器（您不会显示的弹性代码）直接返回yytext。由于yytext指向扫描仪的内部缓冲区，因此它在该实例中看起来很好，但在读取下一个标记后，其值会神秘地改变。如果您有如下的flex规则，则会发生这种情况：

[a-zA-A][a-zA-Z0-9]*    { yylval.var = yytext; return VAR; }

要修复它，您需要先复制yytext，然后再将其复制到解析器中。像

这样的东西

[a-zA-A][a-zA-Z0-9]*    { yylval.var = strdup(yytext); return VAR; }

会做到这一点，但它会让你暴露内存泄漏。

使用Bison构建AST时无效指针

1 个答案: