Question

我是Fortran 90的新手，我正在尝试了解如何将数组传递给函数。我在网上看了一下，我找不到任何清晰简单的例子，所以我决定在这里发帖。

我希望该函数能够处理任意长度的数组（数组的长度不应该是函数的参数之一）。

我试着写一个函数的简单示例，它返回数组元素的总和：

function mysum(arr)
    implicit none
    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
end function mysum

program test
    implicit none
    real, dimension(4) :: a
    real :: mysum,a_sum
    call random_number(a)
    print *,a
    a_sum=mysum(a)
    print *,a_sum
end program

当我尝试编译时，出现以下错误：

array_test.f90:17.14:

 real mysum,a_sum
           1
Error: Procedure 'mysum' at (1) with assumed-shape dummy argument 'arr' must have an explicit interface

我的程序有什么问题？

Answer 1

假定的形状伪参数（具有(:)的参数）需要显式接口到可在呼叫站点处使用的过程。这意味着调用代码必须知道子例程标头的确切位置。另请参阅Module calling an external procedure with implicit interface

可以通过多种方式提供显式界面

1。首选 - 模块程序

module procedures
  implicit none

contains

  function mysum(arr)

    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
  end function mysum
end module

program test
    use procedures

    implicit none
    !no mysum declared here, it comes from the module
    ...
end program

2。内部程序 - 仅适用于简单的简单程序或程序需要访问主机的变量。由于访问主机变量，因此容易出错。

program test
    implicit none
    !no a_sum declared here, it is visible below contains
    ...    
contains

  function mysum(arr)

    !implicit none inherited from the program

    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
  end function mysum
end program

3。界面块 - 根本不推荐，你应该有一些特殊的理由使用它

function mysum(arr)
  ! removed to save space
end function mysum

program test
    implicit none

     interface
       function mysum(arr)
         real, dimension(:), intent(in) :: arr
         real :: mysum
       end function
     end interface

     !no mysum declared there
     !it is declared in the interface block
     ...
end program

具有假定形状伪参数的过程必须具有显式接口

1 个答案: