Question

这个问题仅供娱乐。请不要太认真地对待这个问题。

我目前正在学习F＃，我很想知道是否有一种简洁的方法来定义map4，使用现有函数List.map2，List.map3，管道前进/后退，前进/后退组合等。

即

let map4 f a b c d = ......
map4 f [a1;a2] [b1;b2] [c1;c2] [d1;d2] 

// output: [f(a1,b1,c1,d1); f(a2,b2,c2,d2)]

我可以递归地解决这个问题，或者通过定义一个新的运算符（参见以下URL）

http://www.fssnip.net/9W/title/nary-Seqmap-

http://call-with-cc-en.blogspot.sg/2009/04/applicative-functors-mapping-function.html

我也可以通过组合List.map2和List.map3来解决这个问题，使用部分应用的函数f（a，b，？，？）

let map4 f a b c d =
    List.map3 (fun g y -> g y) (List.map2 f a b) c d

我可以尝试使用正向合成来缩短上面的代码（并使其尽可能抽象/混淆）

let map4 f a =
    List.map2 f a >> List.map3 id;;

// Output type: f:('a -> 'b -> 'c -> 'd -> 'e) ->
// a:'a list -> ('b list -> 'c list -> 'd list -> 'e list)

我想知道我是否可以通过摆脱“f”和“a”进一步缩短它，导致：

let map4 = ...... (* Use only List.map2, List.map3, |>, |<, >>, <<, etc.*) ..........

它可能会让它不必要地混淆，但它会非常酷。谢谢。

编辑：

调整TheInnerLight的答案：

let inline (<!>) f xList = List.map f xList

let inline (<*>) gList xList = List.map2 (id) gList xList

let map4 f w x y z = f <!> w <*> x <*> y <*> z
let map5 f v w x y z = f <!> v <*> w <*> x <*> y <*> z
let map6 f u v w x y z = f <!> u <*> v <*> w <*> x <*> y <*> z

Answer 1

这适用于编程的应用方式，即使用applicative functors。

只需定义apply函数和一些辅助操作符：

module List =
    // val apply : f:('a -> 'b) list -> x:'a list -> 'b list
    let apply f x = List.map2 (fun f x -> f x) f x

    // val inline ( <!> ) : f:('a -> 'b) -> x:'a list -> 'b list
    let inline (<!>) f x = List.map f x

    // val inline ( <*> ) : f:('a -> 'b) list -> x:'a list -> 'b list
    let inline (<*>) f x = apply f x

然后使用map并应用于定义mapN函数。

    // val map2 : f:('a -> 'b -> 'c) -> x:'a list -> y:'b list -> 'c list
    let map2 f x y = f <!> x <*> y

    // val map3 : f:('a -> 'b -> 'c -> 'd) -> x:'a list -> y:'b list -> z:'c list -> 'd list
    let map3 f x y z = f <!> x <*> y <*> z

    // val map4 : f:('a -> 'b -> 'c -> 'd -> 'e) -> x:'a list -> y:'b list -> z:'c list -> a:'d list -> 'e list
    let map4 f x y z a = f <!> x <*> y <*> z <*> a

    // val map8 : f:('a -> 'b -> 'c -> 'd -> 'e -> 'f -> 'g -> 'h -> 'i) -> x:'a list -> y:'b list -> z:'c list -> a:'d list -> b:'e list -> c:'f list -> d:'g list -> e:'h list -> 'i list
    let map8 f x y z a b c d e = f <!> x <*> y <*> z <*> a <*> b <*> c <*> d <*> e

正如您所看到的，您可以不断添加参数来定义您心中的任意mapN。

由于这个问题专门询问使用map2或map3，你可以用相同的风格做到这一点，虽然它不那么简洁，例如：

    let map4_2 f x y z a = List.map2 f x y <*> z <*> a

    let map4_3 f x y z a = List.map3 f x y z <*> a

希望你明白这一点。

作为一小部分，我认为值得注意的是，任何monad都会自动成为一个应用程序仿函数，所以你可以使用这种模式的各种类型，这里有一个Async示例。

module Async = 
    // val map : f:('a -> 'b) -> x:Async<'a> -> Async<'b>
    let map f x = async.Bind(x, async.Return << f)

    // val apply : f:Async<('a -> 'b)> -> x:Async<'a> -> Async<'b>
    let apply f x = async.Bind(f, fun fe -> map fe x)

    // val inline ( <!> ) : f:('a -> 'b) -> x:Async<'a> -> Async<'b>
    let inline (<!>) f x = map f x

    // val inline ( <*> ) : f:Async<('a -> 'b)> -> x:Async<'a> -> Async<'b>
    let inline (<*>) f x = apply f x

    // val map4 : f:('a -> 'b -> 'c -> 'd -> 'e) -> x:Async<'a> -> y:Async<'b> -> z:Async<'c> -> a:Async<'d> -> Async<'e>
    let map4 f x y z a = f <!> x <*> y <*> z <*> a

F＃，使用map2和map3定义map4的简洁方法

1 个答案: