Question

如何从表格列中获取每个唯一值的计数，再加上实际值，计入另一个单元格。

表1的状态栏

**status**  
------  
itemA
itemA
itemB
itemC

单个细胞的预期结果：

Table 1 Status summary |2 itemA, 1 itemB, 1 itemC

我会选择一个简单的逗号分隔列表，列出所有不同值而不计数。

背景信息：我有一个excel文档，用于跟踪新应用程序的验收测试。包含多个工作表的文档（每个工作表代表需要测试的代码区域），每个工作表都有多个表（表示每个案例应该多次或以不同方式测试的测试用例等）然后有一个摘要工作表，我想要快照一下数据。在摘要页面上，每个工作表中的每个表都有一行和一个状态列。在该状态列中，我想显示在相应表中选择的每个状态的计数。我最初创建了一个冗长的公式，如果计数为＆gt;则硬编码值及其计数。 0，但是当我们测试时，我们发现需要添加新的状态值，然后公式变得越来越难以保持更新。

编辑：添加公式 这是我最初在那里的公式

=IF(COUNTIF(Table1[Status],"itemA"),COUNTIF(Table1[Status],"itemA")&" itemA"," ") & IF(COUNTIF(Table1[Status],"itemB"), ", " &COUNTIF(Table1[Status],"itemB")&" itemB"," ") & IF(COUNTIF(Table1[Status],"itemC"), ", " &COUNTIF(Table1[Status],"itemC")&" itemC"," ")

这个问题是，公式在摘要页面上重复了大约100次（对于底层工作表中的每个表一次），每次我想添加一个状态时，我需要编辑每个公式。 / p>

Answer 1

如果您的单元格位于A1:A4，请将此数组公式放在单元格B1:B4中：

{=$A$1:$A$4&": "&COUNTIF($A$1:$A$4,$A$1:$A$4)}

这会创建看起来像itemA: 2和itemB: 1的字符串，但会有重复。

然后，您将使用评论中建议的VBA代码。为了完整起见，我把它放在这里：

Function ConcatUniq(ByRef rng As Range) As String
    Dim r As Range
    Static dic As Object
    If dic Is Nothing Then Set dic = CreateObject("Scripting.Dictionary")
    For Each r In rng
        If r.Value <> Empty Then
            dic(r.Value) = Empty
        End If
    Next
    ConcatUniq = Join$(dic.keys, ", ")
    dic.RemoveAll
End Function

所以你的最终字符串的单元格公式将如下所示：

=ConcatUniq(B1:B4)

Answer 2

此VBA解决方案使用用户定义函数：

.-验证Target Range属于ListObject （Excel表格）。

.-使用Array来保存表格中的所有状态值。

.-使用Control字符串来验证唯一性状态。

.-使用Output字符串来保存具有相应计数的唯一状态列表。

注意：列表的顺序与表中显示的顺序相同。排序不在问题范围内，但如果您希望排序，我建议根据需要对排序ListObject（不包括在内）。

尝试此过程（请参阅代码中包含的注释）：

Private Function Lob_Status_Count(rTrg As Range) As String
Const kStt As String = "Status"
Dim lob As ListObject
Dim sControl As String, sOutput As String
Dim aStt As Variant, vStt As Variant, bStt As Byte
    Rem Validate Input
    On Error Resume Next
    Set lob = rTrg.ListObject               'Set ListObject
    On Error GoTo 0
    If lob Is Nothing Then GoTo ExitTkn     'Exit if Target range is not a ListObject

    With lob.ListColumns(kStt).DataBodyRange

        Rem Set Status Array
        aStt = WorksheetFunction.Transpose(.Value2)

        Rem Set Status Output
        For Each vStt In aStt
            If InStr(sControl, Chr(167) & vStt & Chr(167)) = 0 Then     'Validates uniqueness
                bStt = WorksheetFunction.CountIf(.Cells, vStt)          'Gets Status Count
                sOutput = sOutput & ", " & bStt & " " & vStt            'Adds to Results
                sControl = sControl & Chr(167) & vStt & Chr(167)        'Adds to Control
        End If: Next

        Rem Cleanup Output
        sOutput = Replace(sOutput, ", ", vbNullString, 1, 1)

    End With

    Rem Set Results
    Lob_Status_Count = sOutput

Exit Function
ExitTkn:
    Lob_Status_Count = "!Err ListObject"

End Function

建议阅读以下页面以深入了解所使用的资源：

Using Arrays， ListObject Members (Excel)， WorksheetFunction Object (Excel)，

For Each...Next Statement，InStr Function， On Error Statement

显示表列中每个唯一值的计数

2 个答案: