Question

我想创建一个函数，当你输入一个数字时，它会返回一个从1到5的所有数字的向量，即[1 2 3 4 5]

到目前为止我在

    (defn counter [number]
      (let [x 1
            result []]
       (when (<= x number)
        (conj result x)
        (inc x))))

现在它将1放入向量中但我想现在说(inc x)并再次运行。我必须使用复发吗？

非常感谢任何帮助

Answer 1

来自@ fl00r的答案很好，但我还想提出一个可以减少的答案：

(defn get-range [n]  ;; range/into
  (into [] (range 1 n)))

Reducibles更适合这种用例，因为

range在Clojure 1.7中重建为可自我还原的，对于长开始/步/结束值的特殊情况，它将在自我缩减期间使用原始long。
使用转换器形式意味着可以直接构建最终的矢量，而不是构建一个惰性序列然后将其放入矢量
into将在构建向量时自动使用瞬变 - 对于非常小的范围，开销很小（与循环方法相比），但在较大范围上可以节省大量资金
因为你正在构建一个具体的集合（向量），所以没有懒惰的好处，所以一种渴望的方法更有意义
这种方法比任何序列方法都有更多的时间和内存效率。 range作为可简化的将不会消耗堆空间（只有少数本地人）。通过填充数组然后根据需要直接构建持久向量节点来构建瞬态向量。相比之下，所有序列方法都将在迭代器上进行盒装数学运算，构建多个嵌套的缓存序列值，然后将这些值逐个复制到向量中。上面使用的循环方法将使用原始数学并获得一些性能优势（但仍然具有向量与瞬态逐个添加元素的缺点）。

快速性能测试（适用于各种尺寸的载体）：

Size |     range/vec |   iterate/vec |    loop/recur |   loop/recur' | range/into    |
-----|---------------|---------------|---------------|---------------|---------------|
   1 | 160.968880 ns | 180.287974 ns |  40.373079 ns |  79.203722 ns | 136.157046 ns |
  10 | 378.058753 ns | 851.381372 ns | 342.720391 ns | 200.658997 ns | 253.015756 ns |
 100 |   2.486726 µs |   8.034826 µs |   3.464423 µs |   1.471333 µs |   1.760118 µs |
1000 |  23.349414 µs |  88.188242 µs |  37.247193 µs |  16.443044 µs |  17.109882 µs |

Perf测试是在Java 1.8 / Clojure 1.8上用Criterium快速工作台完成的

测试的版本：

range / vec - 来自@ fl00r的第一个例子 - 原始数学，1个序列，瞬变
iterate / vec - 来自@ fl00r的第二个例子 - 盒装数学，2个序列，瞬变
loop / recur - 来自@ fl00r的第3个例子 - 原始数学，0个序列，没有瞬变
环路/ RECUR＆＃39; - 与先前相同，但修改为使用瞬变 - 原始数学，0序列，瞬变
range / into - 本答案顶部的示例 - 原始数学，0序列，瞬变

请注意，最后两个具有相似的特征，但循环/重复＆＃39;使用了更多代码：

(defn get-range [n]   ;; loop/recur'
  (loop [m 1
         res (transient [])]
    (if (> m n)
      (persistent! res)
      (recur (inc m) (conj! res m)))))

Answer 2

内置函数range。为了实现你的目标（包含数字从1到n的向量），你可以按如下方式包装它：

(defn get-range [n]
  (->> n inc (range 1) vec))

(get-range 5)
#=> [1 2 3 4 5]

此外，您可以使用iterate功能

(defn get-range [n]
  (->> (iterate inc 1)
       (take n)
       vec))

或使用循环：

(defn get-range [n]
  (loop [m 1
         res []]
    (if (> m n)
      res
      (recur (inc m) (conj res m)))))

Clojure - 将所有整数返回到某个数字的函数

2 个答案: