Question

我正在研究Peter Seibel的 Practical Common Lisp 中的MP3数据库示例。 Seibel演示了如何使用宏来缩短where函数的代码;所以现在，我正在尝试使用宏来缩短update函数的代码。（包含update函数的原始版本以供参考。）当我运行我的代码时，以下错误源自倒数第二行 -

*** - CAR: TERMS is not a list

我做错了什么？这是我的代码。

(defvar *db* nil)
(defun add-record (cd) 
  (push cd *db*))

(defun dump-db ()
  (dolist (cd *db*)
    (format t "~{~a:~10t~a~%~}~%" cd)))

(defun make-cd (title artist rating ripped)
  (list :title title :artist artist :rating rating :ripped ripped))

(defun prompt-read (prompt)
  (format *query-io* "~a: " prompt)
  (force-output *query-io*)
  (read-line *query-io*))

(defun prompt-for-cd ()
  (make-cd
    (prompt-read "Title")
    (prompt-read "Artist")
    (or (parse-integer (prompt-read "Rating") :junk-allowed t) 0)
    (y-or-n-p "Ripped [y/n]: ")))

(defun add-cds ()
  (loop (add-record (prompt-for-cd) )
        (if (not (y-or-n-p "Another? [y/n]: ")) (return) )))

(defun save-db (filename)
  (with-open-file (out filename
                       :direction :output
                       :if-exists :supersede)
                  (with-standard-io-syntax
                    (print *db* out))))

(defun load-db (filename)
  (with-open-file (in filename)
                  (with-standard-io-syntax
                    (setf *db* (read in) ))))

(defun select (selector-fn)
  (remove-if-not selector-fn *db*))

(defun make-comparison-expr (field value)
  `(equal (getf cd ,field) ,value))

(defun make-comparison-list (func fields)
  (loop while fields
        collecting (funcall func (pop fields) (pop fields))))

(defmacro where (&rest clauses)
  `#'(lambda (cd) (and ,@(make-comparison-list 'make-comparison-expr clauses))))

(defun make-update-expr (field value)
  `(setf (getf row ,field) ,value))

(defmacro make-update-list (fields)
  (make-comparison-list 'make-update-expr fields))

(defun update (selector-fn &rest terms)
  (print (type-of terms))
  (setf *db*
        (mapcar
          #'(lambda (row)
             (when (funcall selector-fn row)
               (make-update-list terms))
             row)
          *db*)))

;(defun update (selector-fn &key title artist rating (ripped nil ripped-p))
;  (setf *db*
;        (mapcar
;          #'(lambda (row)
;             (when (funcall selector-fn row)
;               (if title    (setf (getf row :title) title) )
;               (if artist   (setf (getf row :artist) artist) )
;               (if rating   (setf (getf row :rating) rating) )
;               (if ripped-p (setf (getf row :ripped) ripped) ))
;             row)
;          *db*)))

(defun delete-rows (selector-fn)
  (setf *db* (remove-if selector-fn *db*)))

;(loop (print (eval (read))))
(add-record (make-cd "Be" "Common" 9 nil))
(add-record (make-cd "Like Water for Chocolate" "Common" 9 nil))
(add-record (make-cd "Be" "Beatles" 9 nil))

(dump-db)
(update (where :artist "Common" :title "Be") :rating 8)
(dump-db)

- - - - - - - - 编辑

我明白了。解决方案是使update成为一个宏并使make-update-list成为一个函数。这样，make-update-list可以在运行时评估字段，而update仍然可以抽象出一些乏味的if语句。以下是更新后的update和make-update-list：

(defun make-update-list (fields)
  (make-comparison-list 'make-update-expr fields))

(defmacro update (selector-fn &rest terms)
  `(setf *db*
        (mapcar
          #'(lambda (row)
             (when (funcall ,selector-fn row)
               ,@(make-update-list terms))
             row)
          *db*)))

Answer 1

make-update-list的宏展开是在一个单独的阶段完成的（称为＆＃34;宏展开阶段＆＃34;） - 这是在编译或加载一段代码时发生的;在这种情况下，我们讨论的是update的编译/加载。宏被扩展，fields绑定到符号 terms，其中（符号本身）用作make-comparison-list中的值;我想这不是你所期望的。

注意，如果你逐行编译文件（Emacs + SLIME中的C-c C-c），它会在{{1}的编译期间告诉你宏扩展失败的原因是＆＃34;值TERMS不是类型LIST＆＃34;。

通常，将宏视为接受其参数未评估的函数 - 即表单update将扩展为宏参数的(make-update-list foo)值绑定到fields。你在这里尝试实现的 - 基于运行时值的代码生成 - 有点难度。

Answer 2

您正在尝试使用符号的car！

> (car 'terms)
*** - CAR: TERMS is not a list

将宏视为一个函数，在使用时，将代码替换为宏函数的结果，无论它在何处使用。此时变量只是符号，除此之外没有任何意义。

执行(make-update-list terms)时，它将调用宏函数，参数fields是您传递的符号，即terms。由于它是一个符号，因此无法像您尝试的那样进行迭代。你可以在运行时迭代它肯定是一个列表，但作为一个宏，它不是一个列表，直到你传递一个像(make-update-list (title artist rating ripped))这样的列表。

如果它在运行时是动态的，那么你的宏需要扩展到在运行时完成大部分魔法的代码。因此，宏只是一个源重写服务，并且不应该与运行时的变量有任何关系，因为它已经完成了它的事情。

为什么lisp说这个参数不是列表？

2 个答案: