关系

Question

我是Cypher的新手，我正试图通过我想要建立的一个小项目来学习它。

到目前为止，我有以下数据模型：

对于每次创建的Thought，我都会Tags通过Categories。 Categories仅作为Tags和Thoughts之间的中间人，这样做是为了改进查询，防止Tag重复并减少对象之间的关系。

为了防止创建具有相同值的新Tags，我想到了以下查询：

CREATE (t: Thought {moment:timestamp(), message:'Testing new Thought'})
MERGE (t1: Tag{value: 'work'})
MERGE (t2: Tag{value: 'tasks'})
MERGE (t3: Tag{value: 'administration'})
MERGE (c: Category)
MERGE (t1)<-[u:CONSISTS_OF{index:0}]-(c)
MERGE (t2)<-[v:CONSISTS_OF{index:1}]-(c)
MERGE (t3)<-[w:CONSISTS_OF{index:2}]-(c)
MERGE (t)-[x:CATEGORIZED_AS{index: 0}]->(c)

这样做很好，除了一件事：Thought收到与所有创建的Categories的关系。 据我所知，我在MERGE查询中没有定义任何限制。

但是，我不知道如何对CATEGORIZED_AS关系应用限制？

我尝试将其添加到查询的底部，但这不起作用：

WHERE (t)-[x]->(c)

知道如何在我的案例中应用我需要的限制吗？

编辑：

我忘了提及Category的唯一连接： 类别按特定顺序连接到固定的Tags集。

E.g我有三个标签：

• 工作
• 任务
• 施用

Category与Thought匹配的唯一方法是Category与Tags具有以下关系：

• work＆lt; - [：CONSISTS_OF {index：0}] - （类别）
• 任务＆lt; - [：CONSISTS_OF {index：1}] - （类别）
• 管理＆lt; - [：CONSISTS_OF {index：2}] - （类别）

任何其他关系顺序无效，应创建新的Category。

Answer 1

问题：使用MERGE

MERGE将尝试在图中找到一个模式，如果找到它将返回它的模式，否则它将尝试创建整个模式。这适用于每个MERGE子句。因此，这对于(n:Tag)节点来说效果很好并且正如预期的那样，因为您只需要为图中的每个单词添加一个标记，但是当您尝试合并类别时，问题会出现在查询中的后面。

您想要做的是尝试找到与这三个(c:Category)节点相关联的(t:Tag)，并在关系(:Tag)-[r:CONSISTS_OF]-() 。但是，您正在运行四个合并子句，它们执行以下操作：

MERGE (c: Category)

查找或创建标签为“Category。”的任何节点c。

MERGE (t1)<-[u:CONSISTS_OF{index:0}]-(c)
MERGE (t2)<-[v:CONSISTS_OF{index:1}]-(c)
MERGE (t3)<-[w:CONSISTS_OF{index:2}]-(c)

查找或创建该节点与t1之间的关系，然后t2，t3等。

如果您要运行该查询，然后将其中一个标记更改为“rest”之类的标记，并再次运行查询，则可能会出现一个新类别。但它不会与当前查询一起，它只是创建一个新标记，然后在第一个(c:Category)子句中找到现有的MERGE节点，并在它与新标记之间创建一个关系。因此，不是将两个类别分别链接到三个标签（共享两个标签），而是只有四个标签全部链接到一个类别，并且关系上有重复的索引。

所以，你真正想做的是使用MERGE找到如下的复杂模式。

MERGE (t1)<-[:CONSISTS_OF {index:0}]-(c:Category)-[:CONSISTS_OF {index:1}]->(t2),
  (t3)<-[:CONSISTS_OF {index:2}]-(c)

令人讨厌的是，这会给你一个语法错误，因为cypher当前无法合并这样的复杂模式。所以，这里有创意。

解决方案1：使用CASE和FOREACH进行条件执行（简单）

对于这些情况，这是一个非常方便的转到，请参阅下面的评论查询。你基本上会拆分合并，使用OPTIONAL MATCH尝试找到模式，然后在cypher语法中使用一个小技巧来CREATE模式，如果我们发现它不存在。

CREATE (t: Thought {moment:timestamp(), message:'Testing new Thought'})
MERGE (t1:Tag{value: 'work'})
MERGE (t2:Tag{value: 'abayo'})
MERGE (t3:Tag{value: 'rest'})
WITH *
// we can't merge this category because it's a complex pattern
// so, can we find it in the db?
OPTIONAL MATCH (t1)<-[:CONSISTS_OF {index:0}]-(c:Category)-[:CONSISTS_OF {index:1}]->(t2),
  (t3)<-[:CONSISTS_OF {index:2}]-(c)
// the CASE here works in conjunction with the foreach to 
// conditionally execute the create clause
WITH t, t1, t2, t3, c, CASE c WHEN NULL THEN [1] ELSE [] END AS make_cat
FOREACH (i IN make_cat |
  // if no such category exists, this code will run as c is null
  // if a category does exist, c will not be null, and so this won't run
  CREATE (t1)<-[:CONSISTS_OF {index:0}]-(new_cat:Category)-[:CONSISTS_OF {index:1}]->(t2),
    (t3)<-[:CONSISTS_OF {index:2}]-(new_cat)
)
// now we're not sure if we're referring to new_cat or cat
// remove variable c from scope
WITH t, t1, t2, t3
// and now match it, we know for sure now we'll find it
// alternatively, use conditional execution again here
MATCH (t1)<-[:CONSISTS_OF]-(c:Category)-[:CONSISTS_OF]->(t2),
  (t3)<-[:CONSISTS_OF]-(c)
// now we have the category, we definitely want 
// to create the relationship between the thought and the category
CREATE (t)-[:CATEGORIZED_AS]->(c)
RETURN *

解决方案2：重构图表（硬）

我这里没有包含查询 - 虽然我可以按要求执行 - 但是另一种方法是重构图形以将标记附加到环（或链 - 带有最终成员标记）结构中的类别，以便你可以直接合并模式，而不必将其拆分。

由于类别在一个订单中，您可以在一个MERGE子句中表达如下所示的数据。

MERGE (c:Category)-[:CONSISTS_OF_TAG_SEQUENCE]->(t1)-[:NEXT_TAG_IN_SEQUENCE]->(t2)-[:NEXT_TAG_IN_SEQUENCE]->(t3)-[:NEXT_TAG_IN_SEQUENCE]->(c)

这看起来似乎是一个简洁的解决方案，但问题是，由于标签属于多个类别，如果标签在类别之间共享，则需要：

1. 创建一个复合索引来识别类别并将其存储为顺序关系的属性，以便您知道路径中要遵循哪些关系（即，您始终可以找到一个类别，只有一个类别的标签序列）
2. 仍然将每个标记链接到它所在的类别并查询此模式（以允许您在＃1中找到单个路径）
3. 使用中间节点实现与1和2相同的
4. 以上所有以上内容。

正如您可能已经猜到的那样，这将使您的查询更加复杂，而不是很快。尝试它可能很有趣，并且可能适合某些用例，但暂时我会坚持使用简单的解决方案！

Answer 2

我对您的问题的解决方案是强制每个类别都具有唯一的，一致可重现的ID。在您的情况下，添加cid或id字段，其中值为tag1<_>tag2<_>tag3<_>。 （<_>被使用是因为成为标记一部分的可能性为零。如果_是无效标记字符，则将<_>替换为_就可以了。

通过这种方式，您可以锁定到类别节点，而无需了解与其关联的节点的任何信息。从本质上讲，唯一ID是您的合并逻辑。这甚至可以使用reduce在Cypher中动态构建。我通常还有value字段作为“漂亮的打印显示ID值”。

当运行最终的Cypher时，您将通过实例id单独合并每个节点，对非节点定义字段使用Set，然后使用Create Unique来确保节点之间只有一个且只有一个关系。