Question

我想在kdb中加入字符串，但效果不佳。这是数据：

tab:([]service:`CS`CS.US`CS.US_ABC;y:1 2 3)


`CS 1
`CS.US  2
`CS.US_ABC  3

我想添加：0和：primary取决于给定的参数。 0现在正在使用

update service:`$(((string[service],'(":"))),'("C"$string 0)) from tab

如果我希望数据成为

`CS:primary 1
`CS.US:primary  2
`CS.US_ABC:primary  3

，主要是字符串或符号，我怎么加入？

我正在参数化0和主要。

目前，0的工作原理如下

update service:`$(((string[service],'(":"))),'( "0")) from tab

但“主要”无效

update service:`$(((string[service],'(":"))),'( "primary")) from tab

Answer 1

如果您希望primary成为参数而不是固定字符串，则以下内容将起作用（在此示例中，primary为“no”）：

q)update {`$string[y],\:":",x}[primary;]service from tab
service      y
--------------
CS:no        1
CS.US:no     2
CS.US_ABC:no 3

如果primary是固定字符串，那么你可以将它放在lambda中代替“x”并将“y”替换为“x”，产生以下内容：

q)update {`$string[x],\:":","primary"}service from tab
service           y
-------------------
CS:primary        1
CS.US:primary     2
CS.US_ABC:primary 3

Answer 2

您的查询会给出长度错误：

q)tab:([]service:`CS`CS.US`CS.US_ABC;y:1 2 3)
q)update service:`$(((string[service],'(":"))),'( "primary")) from tab
'length
  [0]  update service:`$(((string[service],'(":"))),'( "primary")) from tab
                                                    ^

这是因为,'（每个连接）期望两边的向量长度相等，但左边是一个表列大小（3）向量，右边是长度为7的字符向量。注意传递3个字符时会发生什么：

q)update service:`$(((string[service],'(":"))),'( "pri")) from tab
service     y
-------------
CS:p        1
CS.US:r     2
CS.US_ABC:i 3

每一行都有不同的后缀。你想要的是使用,\:（连接每个左）：

q)update service:`$(((string[service],'(":"))),\:( "primary")) from tab
service           y
-------------------
CS:primary        1
CS.US:primary     2
CS.US_ABC:primary 3

为什么它适用于“0”？它起作用，因为“0”不是矢量而是字符标量

q)type "0"
-10h
q)type "primary"
10h

并且右侧有一个标量，,'与.\:的工作方式相同：

q)"ab",'"0"
"a0"
"b0"
q)"ab",\:"0"
"a0"
"b0"

最后，如果您先将“：”添加到后缀，然后将结果附加到每个服务，您的查询将运行得更快：

q)update service:`$(string[service],\:":","primary") from tab
service           y
-------------------
CS:primary        1
CS.US:primary     2
CS.US_ABC:primary 3

Answer 3

  q)update service:`$(((string[service],'(":"))),'(count[i]#enlist "primary")) 
  from tab
  service           y
  -------------------
  CS:primary        1
  CS.US:primary     2
  CS.US_ABC:primary 3

如何在kdb中的表中连接字符串？

3 个答案: