Question

我对terraform相对较新，我正在尝试迭代所有aws_instances以应用null_resource。您是否可以使用多个splats来访问所有实例，无论其名称如何？

EC2实例分为三种类型：

aws_instance.web.* (3 instances)
aws_instance.app.* (3 instances)
aws_instance.db.*  (2 instances)

这是我尝试将null_resource应用于所有八个aws_instances：

resource "null_resource" "install_security_package" {

  #count = "${length(aws_instance)}" #terraform error: resource count can't reference variable: aws_instance
  #count = "${length(aws_instance.*)}" #terraform error: resource variables must be three parts: TYPE.NAME.ATTR
  count = "${length(aws_instance.*.*)}" #terraform error: unknown resource 'aws_instance.*'

  connection {
    type        = "ssh"
    host        = "${element(aws_instance.*.private_ip, count.index)}"
    user        = "${lookup(var.user, var.platform)}"
    private_key = "${file("${var.private_key_path}")}"
    timeout     = "2m"
  }

  provisioner "remote-exec" {
    inline = [
      "sudo rpm -Uvh http://www.example.com/security/repo/security_baseline.rpm",
    ]
  }
}

Answer 1

目前无法匹配给定类型的所有资源。正如您所见，“splat”语法只允许选择从特定资源块创建的所有实例。

今天与Terraform最接近的是将不同的资源连接在一起：

concat(aws_instance.web.*.private_ip, aws_instance.app.*.private_ip, aws_instance.db.*.private_ip)

在本回答的当前版本的Terraform中，有必要使用github issue #4084中共享的一些解决方法，以避免在多个位置复制该复杂表达式。即将推出的名为Local Values的功能将在不久的将来使这个更简单，允许列表被赋予一个名称，以便在多个地方重复使用：

# Won't work until Terraform PR#15449 is merged and released
locals {
  aws_instance_addrs = "${concat(aws_instance.web.*.private_ip, aws_instance.app.*.private_ip, aws_instance.db.*.private_ip)}"
}

resource "null_resource" "install_security_package" {

  count = "${length(local.aws_instance_addrs)}"

  connection {
    type        = "ssh"
    host        = "${local.aws_instance_addrs[count.index]}"
    user        = "${lookup(var.user, var.platform)}"
    private_key = "${file("${var.private_key_path}")}"
    timeout     = "2m"
  }

  provisioner "remote-exec" {
    inline = [
      "sudo rpm -Uvh http://www.example.com/security/repo/security_baseline.rpm",
    ]
  }
}

如何迭代terraform中的所有aws_instances？

1 个答案: