Question

我的一个客户安装程序页面上有一个复选框

${NSD_CreateCheckbox} 0 0 100% 15 "Check to run"
Pop $SvcCheckBox
CreateFont $0 "$(^Font)" "10"
SendMessage $SvcCheckBox ${WM_SETFONT} $0 1
GetFunctionAddress $0 OnCheckbox
nsDialogs::OnClick $SvcCheckBox $0

如果用户回到此页面，我想记住这一点。

我已使用以下代码尝试此操作

${NSD_OnBack} "pageLeave"

FunctionEnd


Function pageLeave
    ${NSD_GetState} $SvcCheckBoxState $SvcCheckBox
FunctionEnd

但是，如果用户取消选中该框，则转到下一页，返回此页面，再次选中该复选框。我需要它不受控制。

如何在页面加载时实现pageLeave复选框状态？

Answer 1

您需要在创建页面时初始化复选框状态。除非您想要在复选框更改时更新页面上的其他内容，否则您不需要On *处理程序。

!include nsDialogs.nsh

Var CheckboxState
Var hCheckbox

Function .onInit
StrCpy $CheckboxState ${BST_CHECKED} ; Set initial/default state
FunctionEnd

Page Components
Page Custom MyPageCreate MyPageLeave
Page Components
Page InstFiles

Function MyPageCreate
nsDialogs::Create 1018
Pop $0

${NSD_CreateCheckbox} 0 0 100% 15 "Check to run"
Pop $hCheckbox
${NSD_SetState} $hCheckbox $CheckboxState

nsDialogs::Show
FunctionEnd

Function MyPageLeave
${NSD_GetState} $hCheckbox $CheckboxState
FunctionEnd

Section
DetailPrint State=$CheckboxState
SectionEnd

在NSIS安装程序中单击后退时，请记住复选框状态

1 个答案: